api/build.gradle.kts at develop · AD-visor/api · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
import org.jetbrains.kotlin.gradle.dsl.JvmTarget

plugins {
	kotlin("jvm") version "2.3.10"
	kotlin("plugin.spring") version "2.3.10"
	id("org.springframework.boot") version "4.0.4" apply false
	id("io.spring.dependency-management") version "1.1.7"
	kotlin("plugin.jpa") version "2.3.10" apply false
	kotlin("kapt") version "2.3.10" apply false
}

group = "com.advisor"
version = "0.0.1-SNAPSHOT"
description = "advisor api server"

allprojects {
	repositories {
		mavenCentral()
	}
}

subprojects {
	apply(plugin = "org.jetbrains.kotlin.jvm")
	apply(plugin = "org.jetbrains.kotlin.plugin.spring")
	apply(plugin = "io.spring.dependency-management")
	apply(plugin = "org.jetbrains.kotlin.plugin.jpa")

	dependencyManagement {
		imports {
			mavenBom("org.springframework.boot:spring-boot-dependencies:4.0.4")
			mavenBom("org.springframework.ai:spring-ai-bom:2.0.0-M4")
			mavenBom("tools.jackson:jackson-bom:3.1.1")
		}
	}

	dependencies {
		// Kotlin
		implementation("tools.jackson.core:jackson-databind")
		implementation("tools.jackson.module:jackson-module-kotlin")
		implementation("org.jetbrains.kotlin:kotlin-reflect")
		implementation("io.github.microutils:kotlin-logging:3.0.5")
		implementation(kotlin("stdlib"))
	}

	java {
		toolchain {
			languageVersion = JavaLanguageVersion.of(25)
		}
	}

	kotlin {
		jvmToolchain(25)
		compilerOptions {
			jvmTarget.set(JvmTarget.JVM_25)
			freeCompilerArgs.add("-Xjsr305=strict")
		}
	}

	allOpen {
		annotation("jakarta.persistence.Entity")
		annotation("jakarta.persistence.MappedSuperclass")
		annotation("jakarta.persistence.Embeddable")
	}

	tasks.withType<Test> {
		useJUnitPlatform()
		failOnNoDiscoveredTests = false
	}

	tasks.withType<Jar> {
		val modulePath = project.path
			.removePrefix(":")
			.replace(":", "-")

		archiveBaseName.set(modulePath)
	}
}