justworks/build.gradle.kts at master · AVSystem/justworks · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
import com.vanniktech.maven.publish.MavenPublishBaseExtension
import com.vanniktech.maven.publish.SonatypeHost

plugins {
    kotlin("jvm") version "2.3.20" apply false
    id("org.jlleitschuh.gradle.ktlint") version "14.2.0" apply false
    id("org.jetbrains.kotlinx.kover") version "0.9.8" apply false
    id("com.vanniktech.maven.publish") version "0.30.0" apply false
}

allprojects {
    group = "com.avsystem.justworks"
    version = System
        .getenv("RELEASE_VERSION")
        ?.let { Regex("""^v(\d+\.\d+\.\d+.*)$""").matchEntire(it)?.groupValues?.get(1) }
        ?: "0.0.1-SNAPSHOT"

    repositories {
        mavenCentral()
    }

    apply(plugin = "org.jlleitschuh.gradle.ktlint")
}

subprojects {
    pluginManager.withPlugin("com.vanniktech.maven.publish") {
        extensions.configure<MavenPublishBaseExtension> {
            publishToMavenCentral(SonatypeHost.CENTRAL_PORTAL)
            signAllPublications()

            pom {
                url = "https://github.com/AVSystem/justworks"

                licenses {
                    license {
                        name = "The Apache License, Version 2.0"
                        url = "https://www.apache.org/licenses/LICENSE-2.0.txt"
                    }
                }

                developers {
                    developer {
                        id = "halotukozak"
                        name = "Bartłomiej Kozak"
                        email = "b.kozak@avsystem.com"
                        organization = "AVSystem"
                        organizationUrl = "https://www.avsystem.com"
                    }
                    developer {
                        id = "mzielu"
                        name = "Marcin Zieliński"
                        email = "m.zielinski@avsystem.com"
                        organization = "AVSystem"
                        organizationUrl = "https://www.avsystem.com"
                    }
                }

                scm {
                    connection = "scm:git:git://github.com/AVSystem/justworks.git"
                    developerConnection = "scm:git:ssh://github.com/AVSystem/justworks.git"
                    url = "https://github.com/AVSystem/justworks"
                }
            }
        }
    }
}