HeadDatabase-API/build.gradle.kts at 433cd82c373f04ecf5a12e274ce2bf52e4a3f634 · Arcaniax-Development/HeadDatabase-API · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
import com.vanniktech.maven.publish.SonatypeHost
import com.diffplug.gradle.spotless.SpotlessPlugin
import java.net.URI

plugins {
    java
    `java-library`
    signing

    id("com.diffplug.spotless") version "8.4.0"
    id("io.github.gradle-nexus.publish-plugin") version "2.0.0"
    id("com.vanniktech.maven.publish") version "0.36.0"

    idea
    eclipse
}

java {
    toolchain.languageVersion.set(JavaLanguageVersion.of(8))
}

configurations.all {
    attributes.attribute(TargetJvmVersion.TARGET_JVM_VERSION_ATTRIBUTE, 8)
}

group = "com.arcaniax"
version = "1.3.3-SNAPSHOT"

repositories {
    maven {
        name = "PaperMC"
        url = uri("https://repo.papermc.io/repository/maven-public/")
    }
}

dependencies {
    compileOnly("com.destroystokyo.paper:paper-api:1.16.5-R0.1-SNAPSHOT")
}

spotless {
    java {
        licenseHeaderFile(rootProject.file("HEADER"))
        target("**/*.java")
    }
}

tasks {

    javadoc {
        val opt = options as StandardJavadocDocletOptions
        opt.links("https://jd.papermc.io/paper/1.21.5/")
        opt.noTimestamp()
    }

    withType<AbstractArchiveTask>().configureEach {
        isPreserveFileTimestamps = false
        isReproducibleFileOrder = true
    }
}


signing {
    if (!project.hasProperty("skip.signing") && !version.toString().endsWith("-SNAPSHOT")) {
        val signingKey: String? by project
        val signingPassword: String? by project
        useInMemoryPgpKeys(signingKey, signingPassword)
        signing.isRequired
        sign(publishing.publications)
    }
}

mavenPublishing {
    coordinates(
            groupId = "$group",
            artifactId = project.name,
            version = "${project.version}",
    )

    pom {
        name.set(project.name)
        description.set("The API for Head Database, a Minecraft plugin that allows you to obtain thousands of custom Minecraft skulls that feature unique designs.")
        url.set("https://github.com/Arcaniax-Development/HeadDatabase-API")

        licenses {
            license {
                name.set("MIT")
                url.set("https://opensource.org/licenses/mit")
                distribution.set("repo")
            }
        }

        developers {
            developer {
                id.set("Arcaniax")
                name.set("Arcaniax")
            }
            developer {
                id.set("NotMyFault")
                name.set("NotMyFault")
                email.set("contact(at)notmyfault.dev")
            }
        }

        scm {
            url.set("https://github.com/Arcaniax-Development/HeadDatabase-API")
            connection.set("scm:git:https://github.com/Arcaniax-Development/HeadDatabase-API.git")
            developerConnection.set("scm:git:git@github.com:Arcaniax-Development/HeadDatabase-API.git")
            tag.set(project.version.toString())
        }

        issueManagement {
            system.set("GitHub")
            url.set("https://github.com/Arcaniax-Development/HeadDatabase-API/issues")
        }

        publishToMavenCentral(SonatypeHost.CENTRAL_PORTAL)
    }
}