alphaSkia/lib/java/build.gradle.kts at 58c9ac0e2282387121f1504fe389d30b868d6a04 · CoderLine/alphaSkia · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
import com.vanniktech.maven.publish.MavenPublishBaseExtension
import java.io.FileInputStream
import java.util.*

plugins {
    alias(libs.plugins.android.library) apply false
    alias(libs.plugins.mavenPublish) apply false
}

val libGroup = "net.alphatab"
var sonatypeSigningKeyId = ""
var sonatypeSigningPassword = ""
var sonatypeSigningKey = ""
var ossrhUsername = ""
var ossrhPassword = ""
var sonatypeStagingProfileId = ""

var libDescription = ""
var libAuthorId = ""
var libAuthorName = ""
var libOrgUrl = ""
var libCompany = ""
var libVersion = "3.1.135"
var libProjectUrl = ""
var libGitUrlHttp = ""
var libGitUrlGit = ""
var libLicenseSpdx = ""
var libLicenseUrl = ""
var libIssuesUrl = ""

val props = Properties()
val propsFile = project.rootProject.file("local.properties")
if (propsFile.exists()) {
    FileInputStream(propsFile).use {
        props.load(it)
    }
}

fun loadSetting(envKey: String, propKey: String, setter: (value: String) -> Unit) {
    if (props.containsKey(propKey)) {
        setter(props.getProperty(propKey))
    } else {
        val env = providers
            .environmentVariable(envKey)
        if (env.isPresent) {
            setter(env.get())
        }
    }
}

loadSetting("OSSRH_USERNAME", "ossrhUsername") { ossrhUsername = it }
loadSetting("OSSRH_PASSWORD", "ossrhPassword") { ossrhPassword = it }
loadSetting("SONATYPE_STAGING_PROFILE_ID", "sonatypeStagingProfileId") { sonatypeStagingProfileId = it }
loadSetting("SONATYPE_SIGNING_KEY_ID", "sonatypeSigningKeyId") { sonatypeSigningKeyId = it }
loadSetting("SONATYPE_SIGNING_PASSWORD", "sonatypeSigningPassword") { sonatypeSigningPassword = it }
loadSetting("SONATYPE_SIGNING_KEY", "sonatypeSigningKey") { sonatypeSigningKey = it }
loadSetting("ALPHASKIA_DESCRIPTION", "alphaskiaDescription") { libDescription = it }
loadSetting("ALPHASKIA_AUTHOR_ID", "alphaskiaAuthorId") { libAuthorId = it }
loadSetting("ALPHASKIA_AUTHOR_NAME", "alphaskiaAuthorName") { libAuthorName = it }
loadSetting("ALPHASKIA_ORG_URL", "alphaskiaOrgUrl") { libOrgUrl = it }
loadSetting("ALPHASKIA_COMPANY", "alphaskiaCompany") { libCompany = it }
loadSetting("ALPHASKIA_VERSION", "alphaskiaVersion") { libVersion = it }
loadSetting("ALPHASKIA_PROJECT_URL", "alphaskiaProjectUrl") { libProjectUrl = it }
loadSetting("ALPHASKIA_GIT_URL_HTTP", "alphaskiaGitUrlHttp") { libGitUrlHttp = it }
loadSetting("ALPHASKIA_GIT_URL_GIT", "alphaskiaGitUrlGit") { libGitUrlGit = it }
loadSetting("ALPHASKIA_LICENSE_SPDX", "alphaskiaLicenseSpdx") { libLicenseSpdx = it }
loadSetting("ALPHASKIA_LICENSE_URL", "alphaskiaLicenseUrl") { libLicenseUrl = it }
loadSetting("ALPHASKIA_ISSUES_URL", "alphaskiaIssuesUrl") { libIssuesUrl = it }

group = libGroup
version = libVersion

subprojects {
    apply<MavenPublishPlugin>()
    apply(plugin = "maven-publish")
    apply(plugin = "signing")

    repositories {
        google()
        mavenCentral()
    }

    group = libGroup
    version = libVersion

    if (!this.project.name.contains("android")) {
        apply<JavaLibraryPlugin>()

        configure<JavaPluginExtension> {
            toolchain {
                languageVersion.set(JavaLanguageVersion.of(17))
            }
        }

        tasks.withType<JavaCompile> {
            options.encoding = "UTF-8"
        }

        tasks.withType<Test> {
            defaultCharacterEncoding = "UTF-8"
        }

        tasks.withType<JavaExec> {
            defaultCharacterEncoding = "UTF-8"
        }

        tasks.withType<Javadoc> {
            options.encoding = "UTF-8"
        }
    }

    afterEvaluate {
        configure<MavenPublishBaseExtension> {
            pom {
                val artifactId = tasks.withType<Jar>().firstOrNull()?.archiveBaseName?.get()
                    ?: throw Exception("Could not find artifact id for maven POM")

                name = artifactId
                description = libDescription
                url = libProjectUrl
                licenses {
                    license {
                        name = libLicenseSpdx
                        url = libLicenseUrl
                    }
                }
                developers {
                    developer {
                        id = libAuthorId
                        name = libAuthorName
                        organization = libCompany
                        organizationUrl = libOrgUrl
                    }
                }
                scm {
                    url = libGitUrlHttp
                    connection = "scm:git:$libGitUrlGit"
                    developerConnection = "scm:git:$libGitUrlGit"
                }
                issueManagement {
                    system = "GitHub"
                    url = libIssuesUrl
                }
            }
        }

        configure<PublishingExtension> {
            repositories {
                maven {
                    name = "DistPath"
                    url = rootProject.projectDir.resolve("dist").toURI()
                }
            }
        }
    }
}