Add files via upload

Author: Philipp Gersch

Examples/demos/Calculator

@@ -0,0 +1,34 @@
+#Simple calculator with input#
+#Should also be an example for functions#
+
+calculate = {
+	num1 = $0; #Better names#
+	num2 = $1;
+	operator = $2;
+
+	ifnot (($num1 typeof num) or ($num2 typeof num))
+	{
+		println "Error";
+		return;
+	};
+
+	if ($operator == +)
+	{
+		return ($num1 + $num2);
+	};
+	if ($operator == -) 
+	{	
+		return ($num1 - $num2);
+	};
+	println "Error, unknown operator: " $operator;
+};
+
+print "Enter first number: ";
+num1 = (input);
+print "Enter second number: ";
+num2 = (input);
+print "Enter operator (+, -): ";
+operator = (input);
+
+println "Calculating...";
+println (call $calculate $num1 $num2 $operator);

Examples/demos/Selection Sort

@@ -0,0 +1,36 @@
+#Selection sort example by DevKev for version 1.9.10#
+
+unsorted = [];
+sorted = [];
+record = 99999;
+index = -1;
+
+for i 200 {
+	unsorted[$i] = (int ((random) * 1000));
+};
+
+println $unsorted;
+
+loop 
+{
+	for i (length $unsorted) 
+	{
+		if ($unsorted[$i] lt $record) 
+		{
+			record = $unsorted[$i];
+			index = $i;
+		};
+	};
+
+	push $unsorted[$index] $sorted;
+	pop $unsorted $index;
+	record = 99999;
+	
+	if ((length $unsorted) == 0) 
+	{
+		break;
+	};
+};
+
+println "Done";
+println $sorted;

Examples/demos/hangman

@@ -0,0 +1,120 @@
+#Hangman by DevKev for version 1.9.10#
+
+words = [tree devscript script java command block array thread];
+word = "";
+guessed = [];
+wordsplit = [];
+blacklist = [];
+
+drawScreen = {
+	try {
+		exec cls;
+		clearConsole;
+	};
+	
+	allright = $true;
+	for i (length $wordsplit) {
+		if ($guessed[$i] != " ") {
+			print $guessed[$i] "\t";
+		} else {
+			print "_\t";
+			allright = $false;
+		};
+	};
+	
+	if $allright {
+		call $drawEndScreen $true;
+		return;
+	};
+
+	println "\n\n";
+	println "LIFE [" $life "]";
+	characters = "";
+	for i (length $blacklist) {
+		characters = (($characters + " ") + $blacklist[$i]);
+	};
+	println "Wrong Guesses: "  $characters;
+	println;
+};
+
+drawEndScreen = {
+	try {
+		exec cls;
+		clearConsole;
+	};
+	
+	if $0 {
+		println " \tY O U    W O N !";
+	} else {
+		println " \tY O U    L O S T !";
+	};
+	println;
+	println "\tThe word was: '" $word "'";
+	println "\tYou had " $life " lives left";
+	println "\n\tPlay again? Press [ENTER]";
+	input;
+	call $chooseWord;
+	call $drawScreen;
+};
+
+guess = {
+	char = $0;
+	for i (length $blacklist) {
+		if ($blacklist[$i] == $char) {
+			println "lool";
+			return $false;
+		};
+	};
+	right = $false;
+	for i (length $wordsplit) {
+		if ($wordsplit[$i] == $char) {
+			guessed[$i] = $char;
+			right = $true;
+		};
+	};
+	return $right;
+};
+
+chooseWord = {
+	life = 10;
+	word = $words[?];
+	guessed = [];
+	wordsplit = [];
+	blacklist = [];
+	for i (stringLength $word) {
+		wordsplit[$i] = (charAt $i $word);
+		guessed[$i] = " ";
+	};
+};
+
+addToBlacklist = {
+	for i (length $blacklist) {
+		if ($blacklist[$i] == $0) {
+			return;
+		};
+	};
+	push $0 $blacklist;
+};
+
+call $chooseWord;
+life = 10;
+loop {
+	call $drawScreen;
+	print "Guess a character: ";
+	character = (input);
+
+	if ((stringLength $character) gt 0) {
+		character = (charAt 0 $character);
+		right = (call $guess $character);
+		ifnot $right {
+			life = ($life - 1);
+			call $addToBlacklist $character;
+			if ($life == 0) {
+				call $drawEndScreen $false;
+			};
+		};
+	};
+}
+
+
+

Examples/tutorials/1 Command Syntax

@@ -0,0 +1,36 @@
+#[EXAMPLE 1: BASIC COMMAND SYNTAX]#
+
+#
+As you can see, you can put comments in your script by putting the text in between two "hashtags"
+Comments are being completely ignored, so you can put them basically everywhere.
+#
+
+#In general, there is a command, that accepts certain arguments:
+Here we have a "println" command, that accepts strings or any
+other datatype. All commands are separated by a ";" and arguments are separated by a space character.
+You can use the "help" command to list all available commands and their arguments#
+	help;
+	println "Hello";
+
+
+#Strings are also recognized without the Quotation marks:#
+	println Hello;
+
+
+#But they are helpful if you want to pass Strings with spaces#
+	println "Hello World";
+
+
+#You can "wrap" multiple commands as arguments for other 
+commands by putting the command in between "(" and ")"
+Here, we add 2 and 2 (=4) and printing the result:
+(Remember, the + is just another command, but the command name is
+shifted to the right. Otherwise, it would look like this: "+ 2 2". Not very readable.#
+	println (2 + 2);
+
+#We can also do more complex command "wrapping" and print it
+But remember, too much of something is never good better split this up with variables (Covered in example 2)#
+	println (int ((random) * 1000));
+
+#To format text, you can just put \n and \t inside strings#
+	println "This is a line\nAnd another line. \tTab";

Examples/tutorials/2 Variables

@@ -0,0 +1,45 @@
+#EXAMPLE 2: VARIABLES#
+
+#You can declare and modify variables using the "=" command (Command name is shifted by one to the right)
+You can put any character into the variable name, except: "$", ".", ";" and obviously space characters.
+Reserved characters like "[", "]", """, "<", ">", "{", "}" may cause weird behaviors.
+So in general, you should avoid reserved characters#
+	foo = "Some text";
+	2 = "More text";
+	=*2_&] = "Why would you even name your variable like this?";
+
+
+#You can access variables by using the "$" character, followed by the variable name#
+	println $foo;
+	println $=*2_&];
+	println $2;
+
+
+#Variables are entirely replaced by their respective value, so theoretically, you can even do this.
+This example will store the command name in a variable and execute it with the given argument:#
+	commandNameAsVariable = println;
+	$commandNameAsVariable $foo; #<- Replaced by 'println "Some text"' and executed at runtime! #
+
+
+#To read variables, you use the "$" sign. But you don't use it to modify variables
+Here we change the value of the variable "foo" to "Changed the text!"#
+	foo = "Changed the text!";
+	println $foo;
+
+
+#This rule of variable modification also applies to arrays (Tutorial 4) and Objects (Tutorial 7):#
+#We print the first array element ("1") but we will change it to "10"#
+	array = [1 2 3];	#More on this in tutorial 3#
+	println $array[0]; 	#<- Access with $ sign#
+	array[0] = 10;	#<- Modify without $ sign#
+	$array[0] = 10;	#This will create a variable with the name "10", since the value of $array[0] is 10#
+	println $array[0];
+	println array[0];	#<- This will just print "array[0]", but not the actual value. You forgot the "$"!#
+	
+	obj = (new-object {}); #More on this in tutorial 5#
+	obj.x = 10;
+	println $obj.x;
+
+
+#You can list all accessible variables and their Block for debug purposes by executing this command#
+	listvars;

Examples/tutorials/3 Conditional Expressions

@@ -0,0 +1,65 @@
+#CONDITIONAL EXPRESSIONS BASICS by DevKev for version 1.9.10#
+
+#To create if statements, you can use the "if [boolean] [block]" command
+Remember, unlike java or similar languages, you still need to use ";" to terminate a command even if it ends with a "}"#
+	variable = $true;
+	if $variable {
+		println "The variable is true!";
+	};
+	
+
+#If statements work like in most programming languages:#
+	if $false {
+		#...#
+	} else {
+		#...#
+	};
+	
+	
+#"elseif" is also possible#
+	if $false {
+		#...#
+	} elseif $true {
+		#...#
+	} else {
+		#...#
+	};
+	
+	
+#You can also use the command [boolean] ? [???] [???]" as ternary expression
+If the condition is true, the 3rd argument is returned, otherwise the 4th#
+	condition = $true;
+	println ($condition ? "Condition is true" "Condition is false");
+	
+	
+#To compare two variables you can use the following commands with the two example Variables $var0 and $var1:
+	"$var0 == $var1" 		<- Returns $true, if $var0's toString() equals $var1
+	"$var0 != $var1"		<- Returns $true, if $var0's toString() does not equal $var1
+	"$var0 lt $var1"		<- Returns $true, if $var0 is less than $var1 (Works only with numbers)
+	"$var0 lteq $var1"		<- Returns $true, if $var0 is less or equal than $var1 (Works only with numbers)
+	"$var0 gt $var1"		<- Returns $true, if $var0 is greater than $var1 (Works only with numbers)
+	"$var0 gteq $var1"		<- Returns $true, if $var0 is greater or equal than $var1 (Works only with numbers)#
+	
+	var0 = 22;
+	var1 = 12;
+	if ($var0 gt $var1) {
+		println "var0 is greater than var1";
+	};
+	
+
+#You can also use logical operators "and" and "or"#
+	result0 = ($true and $false);
+	println $result0;
+	result1 = ($true and $false or $true);
+	println $result1;
+	result1 = (($true and $false) or ($true and $true));
+	println $result1;
+
+#The following example prints, if x is inbetween 10 and 20 or less than 0#
+	x = 20;
+	if (($x gteq 10) and ($x lteq 20) or ($x lt 0)) {
+		println "x is between 10 and 20 or less than 0";
+	} else {
+		println "x is less than 10 and greater than 20 and above zero";
+	};
+