build.gradle

group 'edu.kit.ipd.dbis'
version '0.0.1-SNAPSHOT'

// Allows to build JAR. Implicitly applies the 'java' plugin
apply plugin: 'application'
apply plugin: 'pmd'

// Java version
sourceCompatibility = 1.8
targetCompatibility = 1.8

// Access variables defined below by using $variableName
mainClassName = 'edu.kit.ipd.dbis.Main'

// Gradle searches here for dependencies
// JCenter is a superset of MavenCentral
repositories {
    jcenter()
}

dependencies {
    compile group: 'mysql', name: 'mysql-connector-java', version: '5.1.45'
    compile group: 'org.jgrapht', name: 'jgrapht-core', version: '1.1.0'

    testCompile group: 'junit', name: 'junit', version: '4.12'
    testCompile 'org.mockito:mockito-core:1.+'
}

// Configuration of the java jar plugin.
jar {
    manifest {
        attributes 'Main-Class': "$mainClassName"
    }
}

pmd {
    ignoreFailures = true
}

// Build a single jar file with all the dependencies
task fullJar(type: Jar) {
    manifest {
        attributes 'Main-Class': "$mainClassName"
    }
    baseName = project.name + '-all'
    from {
        configurations.compile.collect {
            it.isDirectory() ? it : zipTree(it)
        }
    }
    with jar
}