Strategy-Game-Engine/build.gradle at main · Entze/Strategy-Game-Engine · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
plugins {
    id 'java'
    id 'java-library'
    id 'idea'
    id "maven-publish"
    id 'com.gradleup.shadow' version '8.3.6'
}

group = 'at.ac.tuwien.ifs.sge'
version = '1.0.5'

java {
    sourceCompatibility = JavaVersion.VERSION_11
}

repositories {
    mavenCentral()
}

dependencies {

    implementation("info.picocli:picocli:4.7.6")
    implementation("com.google.guava:guava:33.4.0-jre")
    testImplementation(platform('org.junit:junit-bom:5.12.0'))
	testImplementation('org.junit.jupiter:junit-jupiter')
	testRuntimeOnly('org.junit.platform:junit-platform-launcher')
}

jar {
    manifest {
        attributes("Main-Class": "at.ac.tuwien.ifs.sge.engine.cli.SgeCommand")
    }
}

java {
    withJavadocJar()
    withSourcesJar()
}

shadowJar {
    archiveClassifier.set('exe')
}

javadoc {
    if (JavaVersion.current().isJava9Compatible()) {
        options.addBooleanOption('html5', true)
    }
}

test {
    useJUnitPlatform()
    maxHeapSize = '1G'
}

tasks.register('generateVersionsYaml') {
    description = 'Generate versions.yaml file with project metadata'
    group = 'Documentation'

    doLast {
        def versionsFile = file('manual/versions.yaml')
        versionsFile.parentFile.mkdirs()

        def yaml = """
# Automatically generated from Gradle properties
SGE_VERSION: ${project.version}
JAVA_VERSION: ${project.sourceCompatibility}
""".trim()

        versionsFile.text = yaml
        println "Generated ${versionsFile.absolutePath}"
    }
}