BeEngine/build.gradle.kts at 3ff270273aa26c00ad9bb01f58d081b1eb7b81f4 · HyPE-Network/BeEngine · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
import com.github.jengelman.gradle.plugins.shadow.transformers.Log4j2PluginsCacheFileTransformer

plugins {
	kotlin("jvm") version "1.9.20"
	id("java-library")
	id("application")
	alias(libs.plugins.shadow)
}

group = "org.distril.beengine"
version = "1.0.0"

repositories {
	mavenLocal()
	mavenCentral()
	maven("https://repo.opencollab.dev/maven-releases")
	maven("https://repo.opencollab.dev/maven-snapshots")
}

dependencies {
	implementation(libs.network) { exclude("org.checkerframework", "checker-qual") }

	implementation(libs.configurate)

	implementation(libs.gson)
	implementation(libs.coroutines)

	implementation(libs.bundles.log4j)
	implementation(libs.bundles.terminal) {
		exclude("org.jline", "jline-reader")
		exclude("org.apache.logging.log4j", "log4j-core")
	}
}

kotlin { jvmToolchain(17) }

java { toolchain { languageVersion.set(JavaLanguageVersion.of(17)) } }

application { mainClass.set("org.distril.beengine.BootstrapKt") }

tasks {
	compileJava {
		options.encoding = Charsets.UTF_8.name()
		options.compilerArgs.addAll(arrayOf("-Xlint:unchecked", "-Xlint:deprecation"))
		options.isIncremental = true
	}

	shadowJar {
		manifest.attributes["Multi-Release"] = "true"

		transform(Log4j2PluginsCacheFileTransformer())

		destinationDirectory.set(file("$projectDir/target"))
		archiveClassifier.set("")
	}
}