LaboratoryBlocks/build.gradle at 53d886c380fbc9be0448d531d42b4a8760ccd48a · IntelligenceModding/LaboratoryBlocks · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
plugins {
    id 'maven-publish'
    id 'net.neoforged.moddev' version '1.0.21'
}

group = 'de.artemis.laboratoryblocks'
version = "${mc_version}-${mod_version}-fusion"

java.toolchain.languageVersion = JavaLanguageVersion.of(21)

wrapper {
    gradleVersion = '8.10'
    distributionType = Wrapper.DistributionType.ALL
}

sourceSets {
    main.resources {
        srcDir 'src/generated/resources'
    }
}

neoForge {
    version = "${neoforge_version}"

    mods {
        laboratoryblocks {
            sourceSet sourceSets.main
        }
    }

    parchment {
        minecraftVersion = "${parchment_mcversion}"
        mappingsVersion = "${parchment_version}"
    }

    runs {
        client {
            client()
            ideName = 'runLaboratoryBlocksClient'
            programArguments = ['--username', 'ArtemisYouTube', '--uuid', '6611b78f-7fbb-4f41-801a-4e85fd0dca3c']
        }

        server {
            server()
            gameDirectory = project.file('server')
            ideName = 'runLaboratoryBlocksServer'
        }

        data {
            data()
            ideName = 'runLaboratoryBlocksData'
            programArguments.addAll '--mod', "laboratoryblocks", '--all', '--output', file('src/generated/resources/').getAbsolutePath(), '--existing', file('src/main/resources/').getAbsolutePath()
        }
    }
}

repositories {
    maven {
        name = "Blamejared maven"
        url = 'https://maven.blamejared.com'
    }
    maven {
        name = "Intelligence Space repository"
        url = "https://maven.pkg.jetbrains.space/intelligence/p/advancedperipherals/ap-repository"
        credentials {
            username = spaceUsername
            password = spacePassword
        }
    }
    maven {
        name = "Modrinth"
        url = "https://api.modrinth.com/maven"
    }
}

dependencies {
    // JEI
    runtimeOnly "mezz.jei:jei-${mc_version}-neoforge:${jei_version}"
    // Fusion
    implementation "maven.modrinth:fusion-connected-textures:${fusion_version}"
}

jar {
    manifest {
        attributes([
                "Specification-Title"     : "laboratoryblocks",
                "Specification-Vendor"    : "Artemis",
                "Specification-Version"   : "${mod_version}",
                "Implementation-Title"    : project.name,
                "Implementation-Version"  : project.jar.archiveVersion,
                "Implementation-Vendor"   : "Artemis"
        ])
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8' // Use the UTF-8 charset for Java compilation
}

tasks.withType(AbstractArchiveTask).configureEach {
    preserveFileTimestamps = false
    reproducibleFileOrder = true
}