Investigate optimizing RelWithDebInfo build for improved runtime performance

[ThomasKroes]

[alxvth]

I think we'll get quite far with changing setups like

if(CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /DWIN32 /EHsc /MP /permissive- /Zc:__cplusplus")
    set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} /MDd")
    set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO} /MD")
    set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} /MD")
endif()

to

if(CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
    set(CMAKE_MSVC_RUNTIME_LIBRARY "MultiThreaded$<$<CONFIG:Debug>:Debug>")
    string(APPEND CMAKE_CXX_FLAGS " /MP /Zc:__cplusplus /Zc:preprocessor")
    string(APPEND CMAKE_CXX_FLAGS_RELEASE " /Zi /Zf")
    string(APPEND CMAKE_SHARED_LINKER_FLAGS_RELEASE " /DEBUG")
    string(APPEND CMAKE_EXE_LINKER_FLAGS_RELEASE " /DEBUG")  # only for the core
endif()

As far as I can tell from CMake's Windows-MSVC.cmake /DWIN32 and /EHsc are already the defaults.

The main differences between RelWithDebugInfo and Release is the addition of the compile option /Zi and the link option /DEBUG which are responsible for generating full PDB files.
I think we can also add /Zf which enables faster PDB generation in parallel builds, which we ensure with /MP.
(It also downgrades the inline function expansion option Ob but we don't need to touch that here since we want to add the missing options to Release mode and are happy with its optimization settings.)

We should also set CMAKE_MSVC_RUNTIME_LIBRARY instead of adding the multi-threaded runtime option multiple times. This will make it clearer that we just want to add specific options to the Release build.

We might want to hide the additional debug options behind a CMake setting like MV_RELWITHDEBUGINFO, which could be OFF by default but explicitly set ON for CI runs:

option(MV_RELWITHDEBUGINFO "Generate program database (PDB) files with debug information for Release builds" OFF)

if(CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
    set(CMAKE_MSVC_RUNTIME_LIBRARY "MultiThreaded$<$<CONFIG:Debug>:Debug>")
    string(APPEND CMAKE_CXX_FLAGS " /MP /Zc:__cplusplus /Zc:preprocessor")

   if(${MV_RELWITHDEBUGINFO})
        string(APPEND CMAKE_CXX_FLAGS_RELEASE " /Zi /Zf")
        string(APPEND CMAKE_SHARED_LINKER_FLAGS_RELEASE " /DEBUG")
        string(APPEND CMAKE_EXE_LINKER_FLAGS_RELEASE " /DEBUG")  # only for the core
    endif()
endif()

---

I already tried to introduce the CMAKE_MSVC_RUNTIME_LIBRARY variable to remove some boilerplate code in #813 but had to revert it in #819 due to some compilation issues on the CI. This might have been caused by an old CMake version on the CI and is hopefully resolved by now.

[alxvth]

Some further thoughts: We'll want to guard the above settings. Otherwise, in a DevBundle setup, each plugin will override or continuously append strings to the CMAKE_* variables.

Introduce helper files:

# cmake/project_defaults.cmake

# Guard: only apply once, even if included multiple times
if(MV_PROJECT_DEFAULTS_APPLIED)
  return()
endif()
set(MV_PROJECT_DEFAULTS_APPLIED TRUE CACHE INTERNAL "")

# Actual options
[...]

Change CMake files:

# CMakeLists.txt

cmake_minimum_required(VERSION 3.22)

# Include defaults - works standalone or as part of superproject
include("${CMAKE_CURRENT_LIST_DIR}/cmake/project_defaults.cmake")

project(...)

[alxvth]

In a future follow up, we should then consider to use CMakePresets.json (see the tutorial) to set all CMAKE_* variables instead of setting them in the CMakeList.txt.

[alxvth]

We should also add /Zc:preprocessor to the CMAKE_CXX_FLAGS.
I first tried to do that in #685 but encountered build issues with MSVC 2019. But since #813 we don't care about that compiler anymore and can enable the preprocessor conformance mode for Visual Studio.
I've updated the above snippets accordingly.

Turns out, /permissive- is implicitly set by the /std:c++20 option, which we use since #813, and we can delete that one now.