KPaperGradle/build.gradle.kts at main · ModLabsCC/KPaperGradle · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
import java.util.*

plugins {
    id("java-gradle-plugin")
    id("org.jetbrains.kotlin.jvm") version "2.0.0"
    id("maven-publish")
    id("org.sonarqube") version "7.0.1.6134"
}

group = "cc.modlabs"
version = System.getenv("VERSION_OVERRIDE") ?: Calendar.getInstance(TimeZone.getTimeZone("UTC")).run {
    "${get(Calendar.YEAR)}.${get(Calendar.MONTH) + 1}.${get(Calendar.DAY_OF_MONTH)}.${String.format("%02d%02d", get(Calendar.HOUR_OF_DAY), get(Calendar.MINUTE))}"
}

repositories {
    maven("https://repo-api.modlabs.cc/repo/maven/maven-mirror/")
}

sonar {
  properties {
    property("sonar.projectKey", "ModLabsCC_KPaperGradle_5b731dbd-626d-43e3-b648-616dcd538d04")
    property("sonar.projectName", "KPaperGradle")
  }
}

gradlePlugin {
    plugins {
        create("kpaperGradle") {
            id = "cc.modlabs.kpaper-gradle"
            implementationClass = "cc.modlabs.kpapergradle.KPaperGradlePlugin"
        }
    }
}

val kpaperVersion = System.getenv("KPAPER_VERSION") ?: "2025.7.15.1527"

tasks.register("generateKPaperVersion") {
    val outputDir = file("src/main/kotlin/cc/modlabs/kpapergradle/internal/")
    inputs.property("kpaperVersion", kpaperVersion)
    outputs.dir(outputDir)
    doLast {
        outputDir.mkdirs()
        val file = File(outputDir, "KPaperVersion.kt")
        file.writeText("""
            package cc.modlabs.kpapergradle.internal
            const val KPAPER_VERSION = "$kpaperVersion"
        """.trimIndent())
    }
}

tasks.withType<org.jetbrains.kotlin.gradle.tasks.KotlinCompile>().configureEach {
    dependsOn("generateKPaperVersion")
}

publishing {
    repositories {
        maven {
            name = "ModLabs"
            url = uri("https://repo-api.modlabs.cc/repo/maven/maven-public/")
            credentials {
                username = System.getenv("NEXUS_USER") ?: "modlabs"
                password = System.getenv("REPO_TOKEN")
            }
        }
        mavenLocal()
    }
    publications {
        create<MavenPublication>("maven") {
            from(components["java"])

            pom {
                name.set("KPaperGradle")
                description.set("Gradle plugin for automatically integrating and delivering KPaper in PaperMC plugin projects.")
                url.set("https://github.com/ModLabsCC/KPaperGradle")
                licenses {
                    license {
                        name.set("GPL-3.0")
                        url.set("https://github.com/ModLabsCC/KPaperGradle/blob/main/LICENSE")
                    }
                }
                developers {
                    developer {
                        id.set("ModLabsCC")
                        name.set("ModLabsCC")
                        email.set("contact@modlabs.cc")
                    }
                }
                scm {
                    connection.set("scm:git:git://github.com/ModLabsCC/KPaperGradle.git")
                    developerConnection.set("scm:git:git@github.com:ModLabsCC/KPaperGradle.git")
                    url.set("https://github.com/ModLabsCC/KPaperGradle")
                }
            }
        }
    }
}