Install sysusers.d config for user/groups

Ubuntu, debian and other distro create the cups user/groups
in their packages.

Add a sysusers.d config file and install it. This configuration
file will create the configured system users/groups on first boot/factory
reset/package installation, without requiring manual scripts or actions.
This is very important for image-based OSes, but it is useful in other
cases too, to allow using declarative configuration instead of scripts.

https://www.freedesktop.org/software/systemd/man/latest/sysusers.d.html

By default if the systemd.pc pkg-config file does not exist, this will
be a no-op, so that it does not affect other OSes.
If systemd.pc exists and contains the installation directory variable,
or if it is specified manually in ./configure, then a sysusers.d config
file is generated based on the configure user/groups and installed.

Add separate files for the cups user/group and for the system groups,
as they can be set independently.

Author: bluca

.gitignore

@@ -31,6 +31,8 @@
 /cgi-bin/testhi.index
 /cgi-bin/testtemplate
 /conf/cups-files.conf
+/conf/cups-sysusers.conf
+/conf/cups-sysusers-groups.conf
 /conf/cupsd.conf
 /conf/mime.convs
 /conf/pam.std

Makedefs.in

@@ -243,6 +243,9 @@ INITDDIR	=	@INITDDIR@
 LAUNCHD_DIR	=	@LAUNCHD_DIR@
 SMFMANIFESTDIR	= 	@SMFMANIFESTDIR@
 SYSTEMD_DIR	=	@SYSTEMD_DIR@
+SYSUSERS_DIR	=	@SYSUSERS_DIR@
+INSTALL_SYSUSERS =	@INSTALL_SYSUSERS@
+INSTALL_SYSUSERS_GROUPS =	@INSTALL_SYSUSERS_GROUPS@
 XINETD		=	@XINETD@
 
 USBQUIRKS	=	@USBQUIRKS@

Makefile

@@ -100,7 +100,7 @@ clean:
 
 distclean:	clean
 	$(RM) Makedefs config.h config.log config.status
-	$(RM) conf/cups-files.conf conf/cupsd.conf conf/mime.convs conf/pam.std conf/snmp.conf
+	$(RM) conf/cups-files.conf conf/cups-sysusers.conf conf/cupsd.conf conf/mime.convs conf/pam.std conf/snmp.conf
 	$(RM) cups.pc
 	$(RM) desktop/cups.desktop
 	$(RM) doc/index.html

conf/Makefile

@@ -91,6 +91,14 @@ install-data:
 			$(INSTALL_DATA) $(PAMFILE) $(BUILDROOT)$(PAMDIR)/cups ; \
 		fi ; \
 	fi
+	-if test x$(SYSUSERS_DIR) != x -a x$(INSTALL_SYSUSERS) != x; then \
+		$(INSTALL_DIR) -m 755 $(BUILDROOT)$(SYSUSERS_DIR); \
+		$(INSTALL_DATA) cups-sysusers.conf $(BUILDROOT)$(SYSUSERS_DIR)/cups.conf; \
+	fi
+	-if test x$(SYSUSERS_DIR) != x -a x$(INSTALL_SYSUSERS_GROUPS) != x; then \
+		$(INSTALL_DIR) -m 755 $(BUILDROOT)$(SYSUSERS_DIR); \
+		$(INSTALL_DATA) cups-sysusers-groups.conf $(BUILDROOT)$(SYSUSERS_DIR)/cups-groups.conf; \
+	fi
 
 
 #
@@ -131,3 +139,8 @@ uninstall:
 		$(RM) $(BUILDROOT)$(PAMDIR)/cups; \
 		$(RMDIR) $(BUILDROOT)$(PAMDIR); \
 	fi
+	-if test x$(SYSUSERS_DIR) != x; then \
+		$(RM) $(BUILDROOT)$(SYSUSERS_DIR)/cups.conf; \
+		$(RM) $(BUILDROOT)$(SYSUSERS_DIR)/cups-groups.conf; \
+		$(RMDIR) $(BUILDROOT)$(SYSUSERS_DIR); \
+	fi

conf/cups-sysusers-groups.conf.in

@@ -0,0 +1,3 @@
+# sysusers.d(5) config file for the CUPS administrative group(s).
+
+@CUPS_SYSUSERS_SYSTEM_GROUPS@

conf/cups-sysusers.conf.in

@@ -0,0 +1,4 @@
+# sysusers.d(5) config file for the CUPS user and group.
+
+@CUPS_SYSUSERS_GROUP@
+@CUPS_SYSUSERS_USER@

config-scripts/cups-defaults.m4

@@ -298,6 +298,49 @@ AC_DEFINE_UNQUOTED([CUPS_DEFAULT_USER], ["$CUPS_USER"], [Default User value.])
 AC_DEFINE_UNQUOTED([CUPS_DEFAULT_GROUP], ["$CUPS_GROUP"], [Default Group value.])
 AC_DEFINE_UNQUOTED([CUPS_DEFAULT_SYSTEM_GROUPS], ["$CUPS_SYSTEM_GROUPS"], [Default SystemGroup value(s).])
 
+dnl sysusers.d entries for CUPS user and group...
+CUPS_SYSUSERS_GROUP=""
+CUPS_SYSUSERS_USER=""
+AS_IF([test "x$CUPS_USER" != "xroot" -a "x$CUPS_USER" != "xnobody"], [
+    AS_IF([test "x$CUPS_GROUP" != "xroot" -a "x$CUPS_GROUP" != "xnobody" -a "x$CUPS_GROUP" != "xnogroup"], [
+	CUPS_SYSUSERS_USER="u $CUPS_USER -:$CUPS_GROUP \"CUPS printing service\""
+    ], [
+	CUPS_SYSUSERS_USER="u $CUPS_USER - \"CUPS printing service\""
+    ])
+], [
+    AS_IF([test "x$CUPS_GROUP" != "xroot" -a "x$CUPS_GROUP" != "xnobody" -a "x$CUPS_GROUP" != "xnogroup"], [
+	CUPS_SYSUSERS_GROUP="g $CUPS_GROUP"
+    ])
+])
+AC_SUBST([CUPS_SYSUSERS_GROUP])
+AC_SUBST([CUPS_SYSUSERS_USER])
+
+AS_IF([test "x$CUPS_SYSUSERS_USER" != x -o "x$CUPS_SYSUSERS_GROUP" != x], [
+    INSTALL_SYSUSERS="install-sysusers"
+], [
+    INSTALL_SYSUSERS=""
+])
+AC_SUBST([INSTALL_SYSUSERS])
+
+CUPS_SYSUSERS_SYSTEM_GROUPS=""
+for group in $CUPS_SYSTEM_GROUPS; do
+    AS_IF([test "x$group" != "xroot" -a "x$group" != "xnobody" -a "x$group" != "xnogroup"], [
+	AS_IF([test "x$CUPS_SYSUSERS_SYSTEM_GROUPS" = x], [
+	    CUPS_SYSUSERS_SYSTEM_GROUPS="g $group"
+	], [
+	    CUPS_SYSUSERS_SYSTEM_GROUPS="$CUPS_SYSUSERS_SYSTEM_GROUPS
+g $group"
+	])
+    ])
+done
+AC_SUBST([CUPS_SYSUSERS_SYSTEM_GROUPS])
+
+AS_IF([test "x$CUPS_SYSUSERS_SYSTEM_GROUPS" != x], [
+    INSTALL_SYSUSERS_GROUPS="install-sysusers-groups"
+], [
+    INSTALL_SYSUSERS_GROUPS=""
+])
+AC_SUBST([INSTALL_SYSUSERS_GROUPS])
 
 dnl Default printcap file...
 AC_ARG_WITH([printcap], AS_HELP_STRING([--with-printcap], [set default printcap file]), [

config-scripts/cups-directories.m4

@@ -284,3 +284,20 @@ AC_ARG_WITH([rundir], AS_HELP_STRING([--with-rundir], [set transient run-time st
 ])
 AC_DEFINE_UNQUOTED([CUPS_STATEDIR], ["$CUPS_STATEDIR"], [Location of transient state files.])
 AC_SUBST([CUPS_STATEDIR])
+
+dnl sysusers.d directory...
+AC_ARG_WITH([sysusersdir], AS_HELP_STRING([--with-sysusersdir], [set directory for sysusers.d config file]), [
+    SYSUSERS_DIR="$withval"
+], [
+    SYSUSERS_DIR=""
+    AS_IF([test "x$PKGCONFIG" != x], [
+	AS_IF([$PKGCONFIG --exists systemd], [
+	    SYSUSERS_DIR="$($PKGCONFIG --variable=sysusersdir systemd)"
+	])
+    ])
+])
+
+AS_IF([test "x$SYSUSERS_DIR" = xno], [
+    SYSUSERS_DIR=""
+])
+AC_SUBST([SYSUSERS_DIR])

configure.ac

@@ -49,6 +49,8 @@ dnl Provide autoconf with a list of files to generate and output them...
 AC_CONFIG_FILES([
     Makedefs
     conf/cups-files.conf
+    conf/cups-sysusers.conf
+    conf/cups-sysusers-groups.conf
     conf/cupsd.conf
     conf/mime.convs
     conf/pam.std