mache/settings.gradle.kts at release/26.1.2 · PaperMC/mache · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
pluginManagement {
    repositories {
        mavenCentral {
            mavenContent { releasesOnly() }
        }
        maven("https://repo.papermc.io/repository/maven-snapshots/") {
            mavenContent { snapshotsOnly() }
        }
        maven("https://repo.papermc.io/repository/maven-releases/") {
            mavenContent { releasesOnly() }
        }
        maven("https://maven.neoforged.net/releases") {
            name = "Neoforged"
            mavenContent {
                releasesOnly()
                includeGroupAndSubgroups("codechicken")
                includeGroupAndSubgroups("net.covers1624")
            }
        }
    }
}

rootProject.name = "mache"

fun formatVersion(version: String): String {
    val replaced = version.replace(".", "_")
    return if (version.first().isLetter()) replaced else "v$replaced"
}

file("versions").listFiles()
    ?.forEach { version ->
        if (version.resolve("build.gradle.kts").exists()) {
            val projectPath = ":versions:${formatVersion(version.name)}"
            include(projectPath)
            findProject(projectPath)!!.projectDir = version
        }
    }