libtape/meson.build at main · Rirusha/libtape · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
project(
  'libtape',
  ['c', 'vala'],
  version: '0.2.1',
  meson_version: '>= 1.0.0',
  license: 'GPL-3.0-or-later',
)

libversion = meson.project_version().replace('.rc', '')

api_version = libversion.split('.')[0]
glib_min_version = '2.76'

lib_name = 'tape'
gir_name = 'Tape'

pkgc_description = 'Unofficial Yandex Music client library'
pkgc_url = 'https://gitlab.gnome.org/Rirusha/libtape'

versioned_name = meson.project_name() + '-' + api_version
versioned_gir_name = gir_name + '-' + api_version

deps_name = versioned_name + '.deps'
header_name = meson.project_name() + '.h'
vapi_name = versioned_name + '.vapi'
gir_name = versioned_gir_name + '.gir'
typelib_name = versioned_gir_name + '.typelib'

pkgconfig = import('pkgconfig')
i18n = import('i18n')
gnome = import('gnome')

deps_pkgs = [
  'gee-0.8',
  'gio-2.0',
  'gstreamer-1.0',
  'libapi-base-7',
  'libxml-2.0',
  'sqlite3',
]

gee_dep = dependency('gee-0.8')
gio_dep = dependency('gio-2.0')
gstreamer_app_dep = dependency('gstreamer-app-1.0')
gstreamer_dep = dependency('gstreamer-1.0')
libapi_base_dep = dependency('libapi-base-7', fallback : ['libapi-base', 'api_base_lib_dep'])
libxml_dep = dependency('libxml-2.0')
sqlite3_dep = dependency('sqlite3')

pgconfig_dependencies = [
  gee_dep,
  gio_dep,
  gstreamer_app_dep,
  gstreamer_dep,
  libxml_dep,
  sqlite3_dep,
]
dependencies = pgconfig_dependencies + [
  libapi_base_dep
]

if libapi_base_dep.type_name() == 'pkgconfig'
  pgconfig_dependencies += libapi_base_dep
endif

add_project_arguments(
  '-DGETTEXT_PACKAGE="@0@"'.format(meson.project_name()),
  '-include', 'config.h',
  '-w',
  language: ['c'],
)

add_project_arguments(
  '--abi-stability',
  '--hide-internal',
  '--target-glib', glib_min_version,
  '--vapidir', meson.current_source_dir(),
  language: ['vala'],
)

conf = configuration_data()
conf.set_quoted('LIBRARY_NAME', gir_name)
conf.set_quoted('GETTEXT_PACKAGE', meson.project_name())
conf.set_quoted('DATADIR', get_option('prefix') / get_option('datadir'))
conf.set_quoted('GNOMELOCALEDIR', get_option('prefix') / get_option('localedir'))

configure_file(output: 'config.h', configuration: conf)
config_h_dir = include_directories('.')

subdir('po')
subdir('lib')
subdir('tests')

if get_option('documentation')
  subdir('doc')
endif

gnome.post_install()