JavaSVSViewer/build.gradle at master · SoarGroup/JavaSVSViewer · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
plugins {
	id 'java'
	id 'application'
	id 'org.javamodularity.moduleplugin' version '1.8.12'
	id 'org.openjfx.javafxplugin' version '0.0.13'
	id 'org.beryx.jlink' version '2.25.0'
}

group 'edu.umich.soar.svsviewer'
version '1.0.3'

repositories {
	mavenCentral()
}

// No need to target a lower version, since we distribute a standalone application
java {
	sourceCompatibility = JavaVersion.VERSION_17
	targetCompatibility = JavaVersion.VERSION_17
}

ext {
	junitVersion = '5.9.2'
}

tasks.withType(JavaCompile).configureEach {
	options.encoding = 'UTF-8'
}

application {
	mainModule = 'edu.umich.soar.svsviewer'
	mainClass = 'edu.umich.soar.svsviewer.SvsViewerApplication'
//	mainClass = 'edu.umich.soar.svsviewer.CubeViewer'
}

javafx {
	version = '21.0.4'
	modules = ['javafx.controls', 'javafx.fxml', 'javafx.swing']
}

dependencies {
	// https://mvnrepository.com/artifact/jakarta.annotation/jakarta.annotation-api
	implementation group: 'jakarta.annotation', name: 'jakarta.annotation-api', version: '3.0.0'

	implementation group: 'com.github.quickhull3d', name: 'quickhull3d', version: '1.0.0'

	implementation 'org.fxyz3d:fxyz3d:0.6.0'

	testImplementation("org.junit.jupiter:junit-jupiter-api:${junitVersion}")
	testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine:${junitVersion}")

	testImplementation group: "org.assertj", name: "assertj-core", version: "3.26.3"
}

test {
	useJUnitPlatform()
}

jlink {
	imageZip = project.file("${buildDir}/distributions/app-${javafx.platform.classifier}.zip")
	options = ['--strip-debug', '--compress', '2', '--no-header-files', '--no-man-pages']
	launcher {
		name = 'SVSViewer'
	}
	// addresses https://github.com/beryx/badass-jlink-plugin/issues/163
	addExtraDependencies("javafx")
	mergedModule {
		// required by quickhull3d, which isn't a module, so we have to add it explicitly here
		requires 'org.slf4j'
	}
}

jlinkZip {
	group = 'distribution'
}

jpackage {
	setApplicationName("SVSViewer")
}