vc/vc_pipeline.nf at main · ToshkaDev/vc · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
#!/usr/bin/env nextflow

/*
 * Pipeline parameters
 */

// file of input files, one per line
params.input_csv = "${projectDir}/data/paired-end.csv"
// folder with the genome index generated by STAR
params.genome_index="${projectDir}/data/genome/genome_index"

// simple genome indices for GATK (and Picard)
params.genome="${projectDir}/data/genome/genome.fa"
params.genome_fai="${projectDir}/data/genome/genome.fa.fai"
params.genome_dict="${projectDir}/data/genome/genome.dict"

// Standard SNPs and indels for GATK
params.snpdb="${projectDir}/data/snp_db/snpdb.vcf.gz"
params.snpdb_index="${projectDir}/data/snp_db/snpdb.vcf.gz.tbi"
params.indels="${projectDir}/data/snp_db/indels.vcf.gz"
params.indels_ndex="${projectDir}/data/snp_db/indels.vcf.gz.tbi"
params.report_name = "multiqc_report"

// SNPs file derived from the 1000 Genomes Project Phase 3 data, aligned to the GRCh38 (hg38) human genome reference
params.gpp3snp="${projectDir}/data/gpp_vcf/1000G_phase3_sites.hg38.vcf"
params.gpp3snp_index="${projectDir}/data/gpp_vcf/1000G_phase3_sites.hg38.vcf.idx"

// File containing RNA editing events
params.rna_edit_sites = "${projectDir}/data/rna_edit_sites/rna_edit_sites.txt"
// File containing low complexity regions with chromosomes
params.lcr_bed = "${projectDir}/data/lcr/lcr_with_chr.bed"

// File containing common variants with allele frequency >= 0.01
params.gpp3snp_af01="${projectDir}/data/gpp_vcf/1000G_phase3_sites.hg38.af01.vcf"
// File containing the latest ncbi dbsnp variants
params.ncbi_dbsnp = "${projectDir}/data/ncbi_dbsnp/ncbi_dbsnp_latest.common.chr.tsv"

// vcf2maf.pl script location
params.vcf2maf_script = "${projectDir}/bin/vcf2maf.pl"
params.vep_data_cache="${projectDir}/data/vep_cache"

// params for annotatevairants process
params.vcftomaf = "${projectDir}/results/vcftomaf"
params.stats_folder = "${projectDir}/results/collectstats"
params.annotatevars_folder = "${projectDir}/results/annotatevariants"
params.starstats_folder = "${projectDir}/results/starstats"
params.file2sample = "${projectDir}/data/file2sample.csv"
params.star_stats_script = "${projectDir}/scripts/star_stats.R"
params.mut_filter_script = "${projectDir}/scripts/mut_filter.R"
params.filter_stats_vis_script = "${projectDir}/scripts/filter_stats_visualize.R"

include { FASTP } from './modules/fastp/main.nf'
include { STAR } from './modules/star/main.nf'
include { STAR_STATS } from './modules/starstats/main.nf'
include { MULTIQC } from './modules/multiqc/main.nf'
include { GATK_ADD_REPLACE_READ_GROUPS } from './modules/gatk/readgroups/main.nf'
include { GATK_MARK_DUPLICATES } from './modules/gatk/markduplicates/main.nf'
include { GATK_SPLIT_NCIGAR_READS } from './modules/gatk/splitncigar/main.nf'
include { GATK_BASE_RECALIBRATOR } from './modules/gatk/baserecalibrate/main.nf'
include { GATK_APPLY_BQSR } from './modules/gatk/applybqsr/main.nf'
include { GATK_HAPLOTYPE_CALLER } from './modules/gatk/haplotypecaller/main.nf'
include { GATK_VARIANT_FILTRATION } from './modules/gatk/variantfiltration/main.nf'
include { FILTER_RNA_EDIT_SITES } from './modules/filterRNAeditsites/main.nf'
include { FILTER_LCRS } from './modules/filterlcrs/main.nf'
include { FILTER_COMMON_VARIANTS } from './modules/filtercommonvars/main.nf'
include { VCF_TO_MAF } from './modules/vcftomaf/main.nf'
include { COMPRESS_MAF_VEP } from './modules/vcftomaf/main.nf'
include { COLLECT_STATS } from './modules/collectstats/main.nf'
include { MERGE_STATS } from './modules/collectstats/main.nf'
include { ANNOTATE_VARIANTS } from './modules/annotatevariants/main.nf'
include { FILTER_STATS_VISUALIZE } from './modules/filterstatsvis/main.nf'

workflow {

    read_ch = Channel.fromPath(params.input_csv)
        .splitCsv(header:true)
        .map { row -> [row.sample_id, file(row.fastq_1), file(row.fastq_2)] }

    FASTP(read_ch)

    STAR(FASTP.out.trimmed_reads, params.genome_index)

    STAR_STATS(STAR.out.logs
        // drop sample_id, keep file
        .map { id, file -> file }
        // gather into one list
        .collect(), params.star_stats_script
    )

    def star_log_paths = STAR.out.logs.map { sample_id, path -> path }
    MULTIQC(FASTP.out.json.mix(star_log_paths).collect(), params.report_name)

    GATK_ADD_REPLACE_READ_GROUPS(STAR.out.bam)

    GATK_MARK_DUPLICATES(GATK_ADD_REPLACE_READ_GROUPS.out.rgs)

    GATK_SPLIT_NCIGAR_READS(GATK_MARK_DUPLICATES.out.dups, params.genome, params.genome_fai,
        params.genome_dict)

    GATK_BASE_RECALIBRATOR(GATK_SPLIT_NCIGAR_READS.out.cigar, params.genome,
        params.genome_fai, params.genome_dict, params.snpdb, params.snpdb_index, params.indels,
        params.indels_ndex)

    GATK_APPLY_BQSR(GATK_BASE_RECALIBRATOR.out.baserecal, params.genome,
        params.genome_fai, params.genome_dict)

    GATK_HAPLOTYPE_CALLER(GATK_APPLY_BQSR.out.bqsrapplied, params.genome,
        params.genome_fai, params.genome_dict, params.gpp3snp, params.gpp3snp_index)

    GATK_VARIANT_FILTRATION(GATK_HAPLOTYPE_CALLER.out.calledsnps, params.genome,
        params.genome_fai, params.genome_dict)

    FILTER_RNA_EDIT_SITES(GATK_VARIANT_FILTRATION.out.filtered_variants, params.rna_edit_sites)

    FILTER_LCRS(FILTER_RNA_EDIT_SITES.out.rnaedit_filtered_vars, params.lcr_bed)

    FILTER_COMMON_VARIANTS(FILTER_LCRS.out.lcr_filtered_vars, params.gpp3snp_af01, params.ncbi_dbsnp)

    all_vcfs = GATK_VARIANT_FILTRATION.out.filtered_variants
        .join(FILTER_RNA_EDIT_SITES.out.rnaedit_filtered_vars)
        .join(FILTER_LCRS.out.lcr_filtered_vars)
        .join(FILTER_COMMON_VARIANTS.out.common_filtered_vars_indels)

    VCF_TO_MAF(all_vcfs, params.genome, params.vep_data_cache)

    COMPRESS_MAF_VEP(VCF_TO_MAF.out.all_maf_vep)

    COLLECT_STATS(STAR_STATS.out.star_stats, GATK_HAPLOTYPE_CALLER.out.calledsnps, all_vcfs, COMPRESS_MAF_VEP.out.compressed_maff, STAR.out.logs)

    MERGE_STATS(COLLECT_STATS.out.stats_files.collect())

    file2_sample = Channel.fromPath(params.file2sample)
    stats_folder = Channel.fromPath(params.stats_folder)

    ANNOTATE_VARIANTS(file2_sample, stats_folder, params.mut_filter_script, MERGE_STATS.out.merged_stats.collect())

    annotatevars_folder = Channel.fromPath(params.annotatevars_folder)
    starstats_folder = Channel.fromPath(params.starstats_folder)

    FILTER_STATS_VISUALIZE(stats_folder, annotatevars_folder, starstats_folder, params.filter_stats_vis_script, ANNOTATE_VARIANTS.out.annotated_vars.collect())

}