node/common/lib/CMakeLists.txt at 38e1199b2834c340293e96f615b2e1132c8e7aed · VILLASframework/node · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
## CMakeLists.txt
#
# Author: Daniel Krebs <github@daniel-krebs.net>
# SPDX-FileCopyrightText: 2014-2023 Institute for Automation of Complex Power Systems, RWTH Aachen University
# SPDX-License-Identifier: Apache-2.0
#
# VILLAScommon


add_library(villas-common SHARED
    base64.cpp
    buffer.cpp
    common.cpp
    compat.cpp
    cpuset.cpp
    dsp/pid.cpp
    hist.cpp
    kernel/kernel.cpp
    kernel/rt.cpp
    list.cpp
    log.cpp
    memory_manager.cpp
    memory.cpp
    plugin.cpp
    popen.cpp
    table.cpp
    task.cpp
    terminal.cpp
    timing.cpp
    tool.cpp
    utils.cpp
    uuid.cpp
    version.cpp
)

if(CMAKE_SYSTEM_PROCESSOR STREQUAL "x86_64")
    target_sources(villas-common PRIVATE tsc.cpp)
endif()

if(CMAKE_SYSTEM_NAME STREQUAL Linux)
    target_sources(villas-common PRIVATE
        kernel/devices/pci_device.cpp
        kernel/vfio_device.cpp
        kernel/vfio_group.cpp
        kernel/vfio_container.cpp
    )
endif()

target_include_directories(villas-common PUBLIC
    ${OPENSSL_INCLUDE_DIR}
    ${CURL_INCLUDE_DIRS}
    ${PROJECT_BINARY_DIR}/common/include
    ${PROJECT_SOURCE_DIR}/common/include
)

target_link_libraries(villas-common PUBLIC
    PkgConfig::JANSSON
    PkgConfig::UUID
    ${OPENSSL_LIBRARIES}
    ${CURL_LIBRARIES}
    ${CMAKE_DL_LIBS}
    spdlog::spdlog
    fmt::fmt
    stdc++
)

if(WITH_CONFIG)
    target_link_libraries(villas-common PUBLIC
        PkgConfig::LIBCONFIG
    )
endif()

target_compile_definitions(villas-common PUBLIC
    -D__STDC_FORMAT_MACROS -D_GNU_SOURCE
)

set_target_properties(villas-common PROPERTIES
    VERSION ${CMAKE_PROJECT_VERSION}
    SOVERSION 1
)

install(
    TARGETS villas-common
    EXPORT VILLASCommonConfig
    COMPONENT lib
    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
)

install(
    DIRECTORY ${CMAKE_SOURCE_DIR}/common/include/villas/
    DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/villas
    COMPONENT devel
    FILES_MATCHING
        PATTERN "*.h"
        PATTERN "*.hpp"
)

install(
    DIRECTORY ${PROJECT_BINARY_DIR}/common/include/villas/
    DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/villas
    COMPONENT devel
    FILES_MATCHING
        PATTERN "*.h"
        PATTERN "*.hpp"
)