postgresql-operator/operator/build.gradle.kts at 2500549cfbffe97327d772b3fbdda708f336b781 · aboutbits/postgresql-operator · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
plugins {
    id("io.quarkus")
}

dependencies {
    /**
     * Quarkus Extensions
     */
    implementation("io.quarkus:quarkus-arc")
    implementation("io.quarkus:quarkus-config-yaml")
    implementation("io.quarkus:quarkus-jackson")
    implementation("io.quarkus:quarkus-jdbc-postgresql")
    implementation("io.quarkus:quarkus-kubernetes-client")
    implementation("io.quarkus:quarkus-logging-json")
    implementation("io.quarkus:quarkus-micrometer")
    implementation("io.quarkus:quarkus-micrometer-registry-prometheus")
    implementation("io.quarkus:quarkus-smallrye-health")

    /**
     * Fabric8 Kubernetes Client
     */
    implementation("io.fabric8:generator-annotations")
    implementation("io.fabric8:crd-generator-api-v2")

    /**
     * jOOQ
     */
    implementation(libs.jooq)
    implementation(project(":generated"))

    /**
     * JSpecify
     */
    implementation(libs.jspecify)

    /**
     * Lombok
     */
    compileOnly(libs.lombok)
    annotationProcessor(libs.lombok)
    testImplementation(libs.lombok)
    testAnnotationProcessor(libs.lombok)

    /**
     * Quarkiverse Helm
     */
    implementation(libs.quarkiverse.helm)

    /**
     * Quarkiverse Operator SDK
     */
    implementation("io.quarkiverse.operatorsdk:quarkus-operator-sdk")
    implementation("io.quarkiverse.operatorsdk:quarkus-operator-sdk-annotations")

    /**
     * SCRAM
     */
    implementation(libs.scram.client)

    /**
     * Testing
     */
    testImplementation("io.quarkus:quarkus-junit")
    testImplementation("io.quarkus:quarkus-junit-mockito")
    testImplementation("org.awaitility:awaitility")
    testImplementation(libs.assertj)
    testImplementation(libs.datafaker)
}

tasks.quarkusAppPartsBuild {
    doNotTrackState("Always execute Gradle task quarkusAppPartsBuild to generate the K8s deploy manifest kubernetes.yml, the CRDs, and to publish the Helm chart")
}

val mockitoAgentProvider = configurations.named("testRuntimeClasspath").map { classpath ->
    classpath.find { it.name.contains("mockito-core") }
}

tasks.withType<Test>().configureEach {
    // Required for the HelmTest
    dependsOn(tasks.quarkusAppPartsBuild)

    jvmArgumentProviders.add(MockitoArgumentProvider(mockitoAgentProvider))
}

class MockitoArgumentProvider(
    @get:Optional
    @get:InputFile
    @get:PathSensitive(PathSensitivity.NONE)
    val agentProvider: Provider<File>
) : CommandLineArgumentProvider {
    override fun asArguments(): Iterable<String> {
        val agentFile = agentProvider.orNull
        return if (agentFile != null) {
            listOf("-javaagent:${agentFile.absolutePath}")
        } else {
            emptyList()
        }
    }
}