Medical GUI - Add customizable message when opening player's medical menu (#10883)

* Display message when opening player's medical menu

* Simplify grammar

Co-authored-by: Will/KJW <100206101+SpicyBagpipes@users.noreply.github.com>

* Update addons/medical_gui/XEH_postInit.sqf

Co-authored-by: PabstMirror <pabstmirror@gmail.com>

* Fix showing message from checking player corpse

* Update addons/medical_gui/XEH_PREP.hpp

Co-authored-by: BrettMayson <brett@mayson.io>

---------

Co-authored-by: Will/KJW <100206101+SpicyBagpipes@users.noreply.github.com>
Co-authored-by: PabstMirror <pabstmirror@gmail.com>
Co-authored-by: BrettMayson <brett@mayson.io>

Author: 4 people

addons/medical_gui/XEH_PREP.hpp

@@ -16,6 +16,7 @@ PREP(onKeyDown);
 PREP(onMenuClose);
 PREP(onMenuOpen);
 PREP(openMenu);
+PREP(showMedicalHint);
 PREP(toggleTriageSelect);
 PREP(updateActions);
 PREP(updateBodyImage);

addons/medical_gui/XEH_postInit.sqf

@@ -42,6 +42,8 @@ GVAR(selfInteractionActions) = [];
     QGVAR(RscPatientInfo) cutFadeOut 0.3;
 }] call CBA_fnc_addEventHandler;
 
+["ace_medicalMenuOpened", LINKFUNC(showMedicalHint)] call CBA_fnc_addEventHandler;
+
 [QEGVAR(medical,woundReceived), {
     params ["_unit", "_allDamages", ""];
     if !(GVAR(peekMedicalOnHit) && {_unit == ACE_player}) exitWith {};

addons/medical_gui/functions/fnc_showMedicalHint.sqf

@@ -0,0 +1,38 @@
+#include "..\script_component.hpp"
+/*
+ * Authors: DartRuffian
+ * Displays a player's medical message to the unit they are treating.
+ *
+ * Arguments:
+ * 0: Medic <OBJECT>
+ * 1: Patient <OBJECT>
+ *
+ * Return Value:
+ * None
+ *
+ * Example:
+ * [player, cursorObject] call ace_medical_gui_fnc_showMedicalHint
+ *
+ * Public: No
+ */
+
+params ["_medic", "_patient"];
+TRACE_2("fnc_showMedicalHint",_medic,_patient);
+
+if (!GVAR(medicalHintEnabled) || GVAR(medicalHintMessage) == "" || GVAR(pendingReopen) ||
+    _medic == _patient || !(_patient call EFUNC(common,isPlayer))
+) exitWith {};
+
+private _message = format [GVAR(medicalHintMessage), [_medic, false, true] call EFUNC(common,getName)];
+_message = format ["<t align='center'>%1</t>", _message];
+private _image = "";
+
+if (GVAR(medicalHintMedicIcon) != "" && {_medic call EFUNC(medical_treatment,isMedic)}) then {
+    if (fileExists GVAR(medicalHintMedicIcon)) then {
+        _image = GVAR(medicalHintMedicIcon);
+    } else {
+        WARNING_1("Image '%1' does not exist.",GVAR(medicalHintMedicIcon));
+    };
+};
+
+[QEGVAR(common,displayTextPicture), [_message, _image, [1, 1, 1], _patient], _patient] call CBA_fnc_targetEvent;

addons/medical_gui/initSettings.inc.sqf

@@ -180,3 +180,30 @@ private _categoryColors = [ELSTRING(medical,Interface_Category), format ["| %1 |
     false,
     false
 ] call CBA_fnc_addSetting;
+
+[
+    QGVAR(medicalHintEnabled),
+    "CHECKBOX",
+    [LSTRING(medicalHintEnabled_DisplayName), LSTRING(medicalHintEnabled_Description)],
+    [ELSTRING(medical,Interface_Category), LSTRING(SubCategory)],
+    true,
+    1
+] call CBA_fnc_addSetting;
+
+[
+    QGVAR(medicalHintMessage),
+    "EDITBOX",
+    [LSTRING(medicalHintMessage_DisplayName), LSTRING(medicalHintMessage_Description)],
+    [ELSTRING(medical,Interface_Category), LSTRING(SubCategory)],
+    LLSTRING(medicalHintMessage_defaultMessage),
+    0
+] call CBA_fnc_addSetting;
+
+[
+    QGVAR(medicalHintMedicIcon),
+    "EDITBOX",
+    [LSTRING(medicalHintMedicIcon_DisplayName), LSTRING(medicalHintMedicIcon_Description)],
+    [ELSTRING(medical,Interface_Category), LSTRING(SubCategory)],
+    "",
+    0
+] call CBA_fnc_addSetting;

addons/medical_gui/stringtable.xml

@@ -1819,5 +1819,27 @@
             <Chinesesimp>慢性创伤</Chinesesimp>
             <Ukrainian>Хронічна травма</Ukrainian>
         </Key>
+        <Key ID="STR_ACE_Medical_GUI_medicalHintEnabled_DisplayName">
+            <English>Medical Menu Message Enabled</English>
+        </Key>
+        <Key ID="STR_ACE_Medical_GUI_medicalHintEnabled_Description">
+            <English>If enabled, patients will have a customizable message displayed when a player opens their medical menu.</English>
+        </Key>
+        <Key ID="STR_ACE_Medical_GUI_medicalHintMessage_defaultMessage">
+            <!-- %1 = medic's name -->
+            <English>%1 is treating you</English>
+        </Key>
+        <Key ID="STR_ACE_Medical_GUI_medicalHintMessage_DisplayName">
+            <English>Medical Menu Message</English>
+        </Key>
+        <Key ID="STR_ACE_Medical_GUI_medicalHintMessage_Description">
+            <English>Custom message to display to patients when opening their medical menu.\n%1 will be your name.</English>
+        </Key>
+        <Key ID="STR_ACE_Medical_GUI_medicalHintMedicIcon_DisplayName">
+            <English>Medical Menu Medic Icon</English>
+        </Key>
+        <Key ID="STR_ACE_Medical_GUI_medicalHintMedicIcon_Description">
+            <English>Image path to display in the medical hint if the player is a medic.</English>
+        </Key>
     </Package>
 </Project>