SolChat/stonecutter.gradle.kts at main · alinco8/SolChat · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
plugins {
    id("dev.kikugie.stonecutter")
    id("me.modmuss50.mod-publish-plugin") version "0.8.4"
}
stonecutter active "1.21.1-fabric"

val modVersion = property("mod.version")!!.toString()

publishMods {
    version = modVersion

    changelog = """
# ${rootProject.name} v$modVersion
${System.getenv("CHANGELOG")}
""".trimIndent()

    type = when {
        "alpha" in modVersion.lowercase() -> ALPHA
        "beta" in modVersion.lowercase() -> BETA
        else -> STABLE
    }
}

tasks.named("publishMods") {
    doFirst {
        val changelog = System.getenv("CHANGELOG")
        if (changelog.isNullOrBlank()) {
            error("Environment variable CHANGELOG is not set or empty. Aborting publish.")
        }
    }
}


allprojects {
    repositories {
        mavenCentral()
        mavenLocal()

        // NeoForge
        maven("https://maven.neoforged.net/releases")
        // Fabric
        maven("https://maven.fabricmc.net/")
        // Forge
        maven("https://files.minecraftforge.net/maven")

        // Stonecutter, FletchingTable
        maven("https://maven.kikugie.dev/releases")
        maven("https://maven.kikugie.dev/snapshots")

        // Kotlin for Forge
        maven("https://thedarkcolour.github.io/KotlinForForge/")

        // Yet Another Config Lib
        maven("https://maven.isxander.dev/releases")

        // Mod Menu
        maven("https://maven.terraformersmc.com/")

        // Quilt
        maven("https://maven.quiltmc.org/repository/release/")

        // Placeholder API
        maven("https://maven.nucleoid.xyz/")
    }
}