nix: Add Nix Package (#31)

Author: Saturn745

flake.lock

@@ -0,0 +1,27 @@
+{
+  description = "IncusScripts CLI";
+
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
+  };
+
+  outputs = {
+    self,
+    nixpkgs,
+  }: let
+    supportedSystems = [
+      "aarch64-linux"
+      "x86_64-linux"
+    ];
+    forAllSystems = f: nixpkgs.lib.genAttrs supportedSystems (system: f system);
+  in {
+    packages = forAllSystems (
+      system: let
+        pkgs = nixpkgs.legacyPackages.${system};
+      in {
+        scripts-cli = pkgs.callPackage ./nix/package.nix {};
+        default = self.packages.${system}.scripts-cli;
+      }
+    );
+  };
+}

flake.nix

@@ -0,0 +1,42 @@
+{
+  lib,
+  buildGo123Module,
+  installShellFiles,
+}:
+buildGo123Module rec {
+  pname = "scripts-cli";
+  version = "latest";
+
+  src = ./../cli;
+
+  vendorHash = "sha256-iPxabKi33tJH8xQ9gPr9XmT0LcBwxtonnXJlJMnYxjw=";
+  subPackages = ["." "./cmd"];
+
+  nativeBuildInputs = [
+    installShellFiles
+  ];
+
+  postInstall = ''
+    # Rename the binary from cli to scripts-cli
+    mv $out/bin/cmd $out/bin/scripts-cli
+
+    installShellCompletion --cmd scripts-cli \
+          --bash <($out/bin/scripts-cli completion bash) \
+          --fish <($out/bin/scripts-cli completion fish) \
+          --zsh <($out/bin/scripts-cli completion zsh)
+  '';
+
+  env.CGO_ENABLED = 0;
+
+  ldflags = [
+    "-X github.com/bketelsen/IncusScripts/cli/cmd/main.commit=${version}"
+  ];
+
+  meta = {
+    description = "Incus Helper-Scripts";
+    homepage = "https://github.com/bketelsen/IncusScripts";
+    license = lib.licenses.mit;
+    mainProgram = "scripts-cli";
+    platforms = lib.platforms.linux;
+  };
+}