databento-cpp/pkg/PKGBUILD at 20bb7e889bcdbc11c8cd59f7c8dc94c7389ca30f · databento/databento-cpp · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
# Maintainer: Databento <support@databento.com>
_pkgname=databento-cpp
pkgname=databento-cpp-git
pkgver=0.51.0
pkgrel=1
pkgdesc="Official C++ client for Databento"
arch=('any')
url="https://github.com/databento/databento-cpp"
license=('Apache-2.0')
depends=('cpp-httplib' 'chrono-date' 'openssl' 'nlohmann-json' 'zstd')
makedepends=('cmake' 'gtest')
source=("${_pkgname}::git+${url}.git")
sha256sums=('SKIP')

pkgver() {
  "${_pkgname}/scripts/get_version.sh"
}

prepare() {
  cmake -S "${_pkgname}" -B build \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX='/usr' \
    -DDATABENTO_USE_EXTERNAL_DATE=ON \
    -DDATABENTO_USE_EXTERNAL_HTTPLIB=ON \
    -DDATABENTO_USE_EXTERNAL_JSON=ON \
    -Wno-dev
}

build() {
  cmake --build build --parallel
}

check() {
  ctest --test-dir build --output-on-failure
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}