databucket-server/build.gradle at master · databucket/databucket-server · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
plugins {
    id 'java'
    id 'org.springframework.boot' version '3.5.12'
    id 'io.spring.dependency-management' version '1.1.7'
}

group = 'pl.databucket'
version = '5.0.1'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
    all*.exclude module: 'spring-boot-starter-logging'
}

repositories {
    mavenCentral()
}

jar {
    enabled = false
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-log4j2'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-security'
    implementation 'org.springframework.boot:spring-boot-starter-actuator'
    implementation 'org.springframework.boot:spring-boot-starter-mail'
    implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.8.9'

    implementation 'org.postgresql:postgresql:42.7.10'
    implementation 'io.jsonwebtoken:jjwt-api:0.13.0'
    runtimeOnly 'io.jsonwebtoken:jjwt-impl:0.13.0'
    runtimeOnly 'io.jsonwebtoken:jjwt-jackson:0.13.0'
    implementation 'org.modelmapper:modelmapper:3.2.6'
    implementation 'com.lmax:disruptor:4.0.0'
    implementation 'commons-io:commons-io:2.21.0'

    compileOnly 'org.projectlombok:lombok:1.18.44'
    annotationProcessor 'org.projectlombok:lombok'
}

test {
    useJUnitPlatform()
    afterSuite { desc, result ->
        if (!desc.parent) {
            println("${result.resultType} " +
                    "(${result.testCount} tests, " +
                    "${result.successfulTestCount} successes, " +
                    "${result.failedTestCount} failures, " +
                    "${result.skippedTestCount} skipped)")
        }
    }
}

import org.apache.tools.ant.taskdefs.condition.Os

tasks.register('deleteStatic') {
    doLast {
        delete "src/main/resources/static"
    }
}

tasks.register('buildFrontend') {
    inputs.dir("frontend")
    doLast {
        String npm = 'npm'
        if (Os.isFamily(Os.FAMILY_WINDOWS)) {
            npm = 'npm.cmd'
        }

        exec {
            workingDir 'frontend'
            commandLine npm, 'install'
        }

        exec {
            workingDir 'frontend'
            commandLine npm, 'run', 'build'
        }
    }
}

tasks.register('copyFrontend') {
    dependsOn tasks.named('buildFrontend')

    doLast {
        copy {
            from "frontend/build"
            into "src/main/resources/static"
        }
    }
}

tasks.named("clean") {
    dependsOn tasks.named("deleteStatic")
}

tasks.named("compileJava") {
    dependsOn tasks.named("copyFrontend")
    mustRunAfter tasks.named("clean")
}
springBoot {
    buildInfo()
}