Sheared/build.gradle.kts at 1.21.11 · devOS-Sanity-Edition/Sheared · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
// versions
val minecraftVersion = "1.21.11"
val minecraftDep = "=1.21.11"
// https://parchmentmc.org/docs/getting-started
val parchmentVersion = "2025.12.20"
// https://fabricmc.net/develop
val loaderVersion = "0.18.4"

// buildscript
plugins {
	id("net.fabricmc.fabric-loom-remap") version "1.15.+"
	id("maven-publish")
}

base.archivesName = "sheared"
group = "one.devos.nautical"

val buildNum = providers.environmentVariable("GITHUB_RUN_NUMBER")
    .filter(String::isNotEmpty)
    .orNull

version = "1.0.0+$minecraftVersion" + if (buildNum != null) { ".build.$buildNum" } else { "" }

repositories {
	maven("https://maven.parchmentmc.org")
	maven("https://api.modrinth.com/maven")
}

dependencies {
	// dev environment
	minecraft("com.mojang:minecraft:$minecraftVersion")
	mappings(loom.layered {
        officialMojangMappings { nameSyntheticMembers = false }
		parchment("org.parchmentmc.data:parchment-$minecraftVersion:$parchmentVersion@zip")
	})
	modImplementation("net.fabricmc:fabric-loader:$loaderVersion")
}

tasks.withType(ProcessResources::class) {
	val properties: Map<String, Any> = mapOf(
		"version" to version,
		"minecraft_dependency" to minecraftDep
	)

	inputs.properties(properties)

	filesMatching("fabric.mod.json") {
		expand(properties)
	}
}

java {
	withSourcesJar()
}

publishing {
	publications {
		register<MavenPublication>("mavenJava") {
			from(components["java"])
		}
	}

	repositories {
		maven("https://mvn.devos.one/snapshots") {
			name = "devOsSnapshots"
			credentials(PasswordCredentials::class)
		}
        maven("https://mvn.devos.one/releases") {
            name = "devOsReleases"
            credentials(PasswordCredentials::class)
        }
	}
}