ci: nix flake

- Keeps track of a certain nushell build that is used for testing out
  the plugin
- Builds the repo using the upstream nixpkgs definition
- Check that the plugin builds/loads with `nix flake check`
- Formats the tree using nixfmt and rustfmt

Author: dtomvan

.gitignore

@@ -13,3 +13,9 @@ target/
 # Added by cargo
 
 /target
+
+# nix-related
+/.direnv
+/.envrc
+/result*
+/repl-result*

flake.lock

@@ -0,0 +1,97 @@
+{
+  description = "Flake for building and testing nu_plugin_dbus";
+
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
+    flake-parts.url = "github:hercules-ci/flake-parts";
+    treefmt-nix = {
+      url = "github:numtide/treefmt-nix";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+    systems.url = "github:nix-systems/default-linux";
+  };
+
+  outputs =
+    inputs@{ flake-parts, ... }:
+    flake-parts.lib.mkFlake { inherit inputs; } {
+      systems = import inputs.systems;
+
+      imports = [
+        inputs.treefmt-nix.flakeModule
+      ];
+
+      perSystem =
+        {
+          pkgs,
+          lib,
+          self',
+          ...
+        }:
+        {
+          treefmt = {
+            programs.nixfmt.enable = true;
+            programs.rustfmt.enable = true;
+          };
+
+          packages.default = pkgs.nushellPlugins.dbus.overrideAttrs (
+            _final: prev: rec {
+              version = "0.15.0"; # used by versionCheckHook, keep in sync with Cargo.toml
+              src = ./.;
+              cargoHash = "";
+              cargoDeps = pkgs.rustPlatform.fetchCargoVendor {
+                inherit src;
+                hash = "sha256-JIEAbzrcfthYSjnyUWEIgNof5SI+EwO4uYflVDMfVE0=";
+              };
+              meta = prev.meta // {
+                broken = false;
+              };
+            }
+          );
+
+          # the nushell build we are currently supporting. Should loosely
+          # follow the upstream nixpkgs build to ensure compatibility with the
+          # latest version of nushell. Used for load-check.
+          packages.nushell = pkgs.nushell.overrideAttrs rec {
+            version = "0.109.1";
+
+            src = pkgs.fetchFromGitHub {
+              owner = "nushell";
+              repo = "nushell";
+              tag = "${version}";
+              hash = "sha256-XNDEfmvmUNS90PU4e/EWFyJeg428R8nFPJHpF3tgRWo=";
+            };
+
+            checkPhase = "";
+            doCheck = false;
+
+            cargoDepsName = "nushell-${version}";
+            cargoHash = "";
+
+            cargoDeps = pkgs.rustPlatform.fetchCargoVendor {
+              inherit src;
+              hash = "sha256-UX0WmvrzrWlrTnvMqaWAxoSie7RzQSC4thEb26LAz+A=";
+            };
+          };
+
+          checks.default =
+            pkgs.runCommand "test-load-${self'.packages.default.name}"
+              {
+                nativeBuildInputs = [ self'.packages.nushell ];
+              }
+              ''
+                touch $out
+                nu --plugins '[${lib.getExe self'.packages.default}]' --plugin-config $out -c 'dbus --help'
+              '';
+
+          devShells.default = pkgs.mkShell {
+            packages = with pkgs; [
+              pkgs.cargo
+              pkgs.rustc
+              dbus
+              pkg-config
+              self'.packages.nushell
+            ];
+          };
+        };
+    };
+}