Guard: Add and use PointsWalkBehavior

This walk behavior is based on the original guard's patrolling implementation.

Author: manuq

scenes/game_elements/characters/enemies/guard/components/guard.gd

@@ -51,8 +51,7 @@ const DEFAULT_SPRITE_FRAMES = preload("uid://ovu5wqo15s5g")
 @export_tool_button("Add/Edit Patrol Path") var _edit_patrol_path: Callable = edit_patrol_path
 ## The path the guard follows while patrolling.
 @export var patrol_path: Path2D:
-	set(new_value):
-		patrol_path = new_value
+	set = _set_patrol_path
 
 ## The wait time at each patrol point.
 @export_range(0, 5, 0.1, "or_greater", "suffix:s") var wait_time: float = 1.0:
@@ -108,6 +107,9 @@ var _player: Node2D
 ## Control to hold debug info that can be toggled on or off.
 @onready var debug_info: Label = %DebugInfo
 
+## Behavior to use when patrolling.
+@onready var patrolling_behavior: PointsWalkBehavior = %PatrollingBehavior
+
 ## Reference to the node controlling the AnimationPlayer for walking / being idle,
 ## so it can be disabled to play the alerted animation.
 @onready
@@ -149,6 +151,8 @@ func _ready() -> void:
 			player_awareness.max_value = time_to_detect_player
 			player_awareness.value = 0.0
 
+	patrolling_behavior.speeds.walk_speed = move_speed
+	_set_patrol_path(patrol_path)
 	_set_sprite_frames(sprite_frames)
 
 	if detection_area:
@@ -163,8 +167,9 @@ func _ready() -> void:
 	guard_movement.path_blocked.connect(self._on_path_blocked)
 
 	# Wait 2 frames before starting to match backwards compatibility.
-	await get_tree().process_frame
-	await get_tree().process_frame
+	if not Engine.is_editor_hint():
+		await get_tree().process_frame
+		await get_tree().process_frame
 
 	_advance_target_patrol_point()
 	state = State.WAITING
@@ -177,8 +182,11 @@ func _process(delta: float) -> void:
 		return
 
 	match state:
-		State.PATROLLING, State.WAITING, State.DETECTING, State.INVESTIGATING, State.RETURNING:
+		State.WAITING, State.INVESTIGATING, State.RETURNING:
 			guard_movement.move()
+		State.DETECTING:
+			if _previous_state != State.PATROLLING:
+				guard_movement.move()
 
 	if state != State.ALERTED:
 		_update_player_awareness(delta)
@@ -224,6 +232,13 @@ func _update_debug_info() -> void:
 			debug_info.text += "%s: %.2f\n" % ["time left", waiting_timer.time_left]
 		State.DETECTING, State.INVESTIGATING, State.RETURNING:
 			debug_info.text += "%s: %s\n" % ["breadcrumbs", breadcrumbs.size()]
+		State.PATROLLING:
+			debug_info.text += (
+				"%s: %s\n" % ["previous_patrol_point_idx", patrolling_behavior.previous_point_index]
+			)
+			debug_info.text += (
+				"%s: %s\n" % ["current_patrol_point_idx", patrolling_behavior.current_point_index]
+			)
 		_:
 			debug_info.text += "%s: %s\n" % ["previous_patrol_point_idx", previous_patrol_point_idx]
 			debug_info.text += "%s: %s\n" % ["current_patrol_point_idx", current_patrol_point_idx]
@@ -232,9 +247,6 @@ func _update_debug_info() -> void:
 ## What happens when the guard reached the point it was walking towards
 func _on_destination_reached() -> void:
 	match state:
-		State.PATROLLING:
-			state = State.WAITING
-			_advance_target_patrol_point()
 		State.INVESTIGATING:
 			state = State.WAITING
 		State.RETURNING:
@@ -250,14 +262,6 @@ func _on_destination_reached() -> void:
 ## stuck with a collider.
 func _on_path_blocked() -> void:
 	match state:
-		State.PATROLLING:
-			state = State.WAITING
-			# This check makes sure that if the guard is blocked on start,
-			# they won't try to set an invalid patrol point as destination.
-			if previous_patrol_point_idx > -1:
-				var new_patrol_point: int = previous_patrol_point_idx
-				previous_patrol_point_idx = current_patrol_point_idx
-				current_patrol_point_idx = new_patrol_point
 		State.INVESTIGATING:
 			state = State.RETURNING
 		State.RETURNING:
@@ -277,12 +281,14 @@ func _set_state(new_state: State) -> void:
 
 	match state:
 		State.PATROLLING:
-			var target_position: Vector2 = _patrol_point_position(current_patrol_point_idx)
-			guard_movement.set_destination(target_position)
+			patrolling_behavior.process_mode = Node.PROCESS_MODE_INHERIT
 		State.DETECTING:
+			if _previous_state != State.PATROLLING:
+				patrolling_behavior.process_mode = Node.PROCESS_MODE_DISABLED
 			if not _alert_sound.playing:
 				_alert_sound.play()
 		State.ALERTED:
+			patrolling_behavior.process_mode = Node.PROCESS_MODE_DISABLED
 			character_animation_player_behavior.process_mode = Node.PROCESS_MODE_DISABLED
 			if not _alert_sound.playing:
 				_alert_sound.play()
@@ -292,9 +298,13 @@ func _set_state(new_state: State) -> void:
 			player_awareness.visible = true
 			guard_movement.stop_moving()
 		State.INVESTIGATING:
+			patrolling_behavior.process_mode = Node.PROCESS_MODE_DISABLED
 			breadcrumbs.push_back(global_position)
 		State.WAITING:
+			patrolling_behavior.process_mode = Node.PROCESS_MODE_DISABLED
 			waiting_timer.start()
+		State.RETURNING:
+			patrolling_behavior.process_mode = Node.PROCESS_MODE_DISABLED
 
 
 ## Calculate and set the next point in the patrol path.
@@ -452,6 +462,12 @@ func _set_alert_other_sound_stream(new_value: AudioStream) -> void:
 	_torch_hit_sound.stream = new_value
 
 
+func _set_patrol_path(new_patrol_path: Path2D) -> void:
+	patrol_path = new_patrol_path
+	if patrolling_behavior:
+		patrolling_behavior.walking_path = patrol_path
+
+
 func _set_wait_time(new_wait_time: float) -> void:
 	wait_time = new_wait_time
 	waiting_timer.wait_time = wait_time
@@ -489,3 +505,11 @@ func _on_waiting_timer_timeout() -> void:
 			state = State.PATROLLING
 		State.INVESTIGATING:
 			state = State.RETURNING
+
+
+func _on_patrolling_behavior_point_reached() -> void:
+	state = State.WAITING
+
+
+func _on_patrolling_behavior_got_stuck() -> void:
+	state = State.WAITING

scenes/game_elements/characters/enemies/guard/guard.tscn

@@ -5,12 +5,21 @@
 [ext_resource type="Texture2D" uid="uid://8t6ihmesvghq" path="res://scenes/game_elements/characters/enemies/guard/components/field_of_view.png" id="3_0hjcv"]
 [ext_resource type="Script" uid="uid://cu7ujf83r7yh2" path="res://scenes/game_logic/walk_behaviors/points_walk_behavior.gd" id="3_mswbt"]
 [ext_resource type="Texture2D" uid="uid://c75ofhy3swhj3" path="res://scenes/game_elements/characters/enemies/guard/components/exclamation_mark.png" id="3_pnkgp"]
+[ext_resource type="Script" uid="uid://csev4hv57utxv" path="res://scenes/game_logic/walk_behaviors/character_speeds.gd" id="4_innil"]
 [ext_resource type="Script" uid="uid://cxsi2xqcdyw7g" path="res://scenes/game_elements/characters/enemies/guard/components/light.gd" id="4_lptvm"]
 [ext_resource type="Script" uid="uid://bnbt0iw1a1w6" path="res://scenes/game_elements/characters/enemies/guard/components/detection_area.gd" id="4_mswbt"]
 [ext_resource type="SpriteFrames" uid="uid://ovu5wqo15s5g" path="res://scenes/quests/template_quests/NO_EDIT/1_NO_EDIT_stealth/NO_EDIT_stealth_components/NO_EDIT_guard_enemy.tres" id="5_mswbt"]
 [ext_resource type="Script" uid="uid://dy68p7gf07pi3" path="res://scenes/game_logic/sprite_behaviors/character_sprite_behavior.gd" id="7_klpct"]
 [ext_resource type="Script" uid="uid://b3hx1n2yl88qr" path="res://scenes/game_logic/character_animation_player_behavior.gd" id="9_8vt0k"]
 
+[sub_resource type="Resource" id="Resource_2e3xr"]
+script = ExtResource("4_innil")
+walk_speed = 200.0
+metadata/_custom_type_script = "uid://csev4hv57utxv"
+
+[sub_resource type="Resource" id="Resource_innil"]
+script = ExtResource("4_innil")
+
 [sub_resource type="CircleShape2D" id="CircleShape2D_g173s"]
 radius = 35.0
 
@@ -219,13 +228,15 @@ one_shot = true
 unique_name_in_owner = true
 process_mode = 4
 script = ExtResource("3_mswbt")
+speeds = SubResource("Resource_2e3xr")
 character = NodePath("..")
 metadata/_custom_type_script = "uid://cu7ujf83r7yh2"
 
 [node name="ReturningBehavior" type="Node2D" parent="." unique_id=641161332 node_paths=PackedStringArray("character")]
 unique_name_in_owner = true
 process_mode = 4
 script = ExtResource("3_mswbt")
+speeds = SubResource("Resource_innil")
 character = NodePath("..")
 metadata/_custom_type_script = "uid://cu7ujf83r7yh2"
 
@@ -356,6 +367,8 @@ max_distance = 500.0
 bus = &"SFX"
 
 [connection signal="timeout" from="WaitingTimer" to="." method="_on_waiting_timer_timeout"]
+[connection signal="got_stuck" from="PatrollingBehavior" to="." method="_on_patrolling_behavior_got_stuck"]
+[connection signal="point_reached" from="PatrollingBehavior" to="." method="_on_patrolling_behavior_point_reached"]
 [connection signal="body_entered" from="InstantDetectionArea" to="." method="_on_instant_detection_area_body_entered"]
 [connection signal="body_entered" from="DetectionArea" to="." method="_on_detection_area_body_entered"]
 [connection signal="body_exited" from="DetectionArea" to="." method="_on_detection_area_body_exited"]

scenes/game_logic/walk_behaviors/points_walk_behavior.gd

@@ -0,0 +1,149 @@
+# SPDX-FileCopyrightText: The Threadbare Authors
+# SPDX-License-Identifier: MPL-2.0
+@tool
+class_name PointsWalkBehavior
+extends BaseCharacterBehavior
+## @experimental
+##
+## Make the character walk through the points of a path.
+##
+## If the path is closed the character walks in circles. If not, they walk back and forth turning
+## around in endings.
+## [br][br]
+## If the character gets stuck while walking the path, they turn around.
+
+## Emitted when a point of the path is reached.
+## This could be used to wait standing for a bit in these points.
+signal point_reached
+
+## Emitted when [member character] got stuck while walking the path.
+signal got_stuck
+
+## Parameters controlling the speed at which this character walks. If unset, the default values of
+## [CharacterSpeeds] are used.
+@export var speeds: CharacterSpeeds
+
+## The walking path.
+@export var walking_path: Path2D:
+	set = _set_walking_path
+
+## Index of the previous patrol point, -1 means that there isn't a previous
+## point yet.
+var previous_point_index: int = -1
+
+## Index of the current patrol point.
+var current_point_index: int = 0
+
+## The walking target position.
+var target_position: Vector2
+
+## True if the [member walking_path] is closed, in which case the character will walk in
+## circles.
+var is_path_closed: bool
+
+
+func _set_walking_path(new_walking_path: Path2D) -> void:
+	walking_path = new_walking_path
+	update_configuration_warnings()
+	if walking_path:
+		_advance_target_patrol_point()
+		var local_point_position: Vector2 = walking_path.curve.get_point_position(
+			current_point_index
+		)
+		target_position = walking_path.to_global(local_point_position)
+
+
+func _get_configuration_warnings() -> PackedStringArray:
+	var warnings := super._get_configuration_warnings()
+	if not walking_path:
+		warnings.append("Walking Path property must be set.")
+	return warnings
+
+
+func _ready() -> void:
+	super._ready()
+
+	if not speeds:
+		speeds = CharacterSpeeds.new()
+
+	_set_walking_path(walking_path)
+
+
+func _physics_process(delta: float) -> void:
+	character.velocity = character.global_position.direction_to(target_position) * speeds.walk_speed
+	character.move_and_slide()
+
+	var collision: KinematicCollision2D = character.get_last_slide_collision()
+
+	# If the distance it was able to travel is a lot lower than the remainder,
+	# it's stuck and we can emit the path_blocked signal so the guard can
+	# handle that case
+	if collision and collision.get_travel().length() < collision.get_remainder().length() / 20.0:
+		if previous_point_index > -1:
+			var new_patrol_point: int = previous_point_index
+			previous_point_index = current_point_index
+			current_point_index = new_patrol_point
+		got_stuck.emit()
+
+	if (
+		(
+			character.global_position.distance_to(target_position)
+			<= character.velocity.length() * delta
+		)
+		and walking_path
+	):
+		_advance_target_patrol_point()
+		var local_point_position: Vector2 = walking_path.curve.get_point_position(
+			current_point_index
+		)
+		target_position = walking_path.to_global(local_point_position)
+		point_reached.emit()
+
+
+## Return true if the end of the path is the same point as the beginning.
+func _is_path_closed() -> bool:
+	if walking_path.curve.point_count < 3:
+		return false
+
+	var first_point_position: Vector2 = walking_path.curve.get_point_position(0)
+	var last_point_position: Vector2 = walking_path.curve.get_point_position(
+		walking_path.curve.point_count - 1
+	)
+
+	return first_point_position.is_equal_approx(last_point_position)
+
+
+## Calculate and set the next point in the patrol path.
+## The guard would circle back if the path is open, and go in rounds if the
+## path is closed.
+func _advance_target_patrol_point() -> void:
+	# TODO: Assume as existing and add an editor warning instead.
+	if not walking_path or not walking_path.curve or walking_path.curve.point_count < 2:
+		return
+
+	var new_patrol_point_idx: int
+
+	if _is_path_closed():
+		# amount of points - 1 is used here because in a closed path, the
+		# last and first patrol points are the same. So, this lets us skip
+		# that repeated point and go for the first one that is different
+		new_patrol_point_idx = (current_point_index + 1) % (walking_path.curve.point_count - 1)
+	else:
+		var at_last_point: bool = current_point_index == (walking_path.curve.point_count - 1)
+		var at_first_point: bool = current_point_index == 0
+		var going_backwards_in_path: bool = previous_point_index > current_point_index
+		if at_last_point:
+			# When reaching the end of the path, it starts walking back
+			new_patrol_point_idx = current_point_index - 1
+		elif at_first_point:
+			# If it's at first point is either because it was walking back
+			# or because it's the first time it will move, in any case, it moves
+			# forward
+			new_patrol_point_idx = current_point_index + 1
+		elif going_backwards_in_path:
+			new_patrol_point_idx = current_point_index - 1
+		else:
+			new_patrol_point_idx = current_point_index + 1
+
+	previous_point_index = current_point_index
+	current_point_index = new_patrol_point_idx

scenes/game_logic/walk_behaviors/points_walk_behavior.gd.uid

@@ -0,0 +1 @@
+uid://cu7ujf83r7yh2