Settings: Add option to disable the input HUD (#2133)

Settings: Add option to disable the input HUD

I wanted this for a slightly cleaner screenshot.

Rather than duplicating the code from the fullscreen toggle, make the
script more generic. It now toggles a named property on the Settings
singleton. Use the existing fullscreen methods as the getter/setter of a
new property, and add a new property for whether the input HUD is
visible.

Remove a stale signal connection from the video_settings scene - the
target method does not exist.

Author: wjt

scenes/globals/settings/settings.gd

@@ -15,6 +15,9 @@ const DEFAULT_VOLUMES: Dictionary[String, float] = {
 	"Music": 0.5,
 }
 
+const DISPLAY_SECTION := "Display"
+const SHOW_HUD_KEY := "Show HUD"
+
 const LANGUAGE_SECTION := "Language"
 const LOCALE_KEY := "Locale"
 const DEFAULT_LOCALE := "en"
@@ -25,6 +28,17 @@ const MINIMUM_ASPECT_RATIO := 1.25
 ## An arbitrary wide ratio, lower than 21:9 ("ultrawide").
 const MAXIMUM_ASPECT_RATIO := 2.2
 
+@export var fullscreen: bool:
+	get = is_fullscreen,
+	set = set_fullscreen
+
+@export var show_input_hud := true:
+	get:
+		return _settings.get_value(DISPLAY_SECTION, SHOW_HUD_KEY, true)
+	set(new_value):
+		_settings.set_value(DISPLAY_SECTION, SHOW_HUD_KEY, new_value)
+		_save()
+
 var _settings := ConfigFile.new()
 
 var _overrides_path: String
@@ -99,7 +113,7 @@ func is_fullscreen() -> bool:
 	return DisplayServer.window_get_mode() == DisplayServer.WINDOW_MODE_EXCLUSIVE_FULLSCREEN
 
 
-func toggle_fullscreen(toggled_on: bool) -> void:
+func set_fullscreen(toggled_on: bool) -> void:
 	if toggled_on:
 		set_window_mode(DisplayServer.WINDOW_MODE_EXCLUSIVE_FULLSCREEN)
 	else:

scenes/menus/options/components/fullscreen_toggle.gd

@@ -0,0 +1,46 @@
+# SPDX-FileCopyrightText: The Threadbare Authors
+# SPDX-License-Identifier: MPL-2.0
+@tool
+extends CheckButton
+## A [CheckButton] that toggles a property of [Settings].
+
+## The name of a property of the [Settings] singleton.
+@export var setting: StringName:
+	set = set_setting
+
+
+func set_setting(new_value: StringName) -> void:
+	setting = new_value
+	update_configuration_warnings()
+
+
+func _get_configuration_warnings() -> PackedStringArray:
+	var warnings: PackedStringArray
+
+	if not setting:
+		warnings.append("Setting name is not set.")
+	elif setting not in Settings:
+		warnings.append("Settings singleton has no property named " + setting)
+
+	return warnings
+
+
+func _ready() -> void:
+	if Engine.is_editor_hint():
+		return
+
+	# There are two instances of this toggle in the game: one on the title screen, and
+	# another in the pause overlay. At most one is displayed at a time, so we can keep them in
+	# synch by reading the setting each time each toggle is displayed.
+	visibility_changed.connect(_refresh)
+	_refresh()
+
+	toggled.connect(_on_toggled)
+
+
+func _refresh() -> void:
+	set_pressed_no_signal(Settings.get(setting))
+
+
+func _on_toggled(toggled_on: bool) -> void:
+	Settings.set(setting, toggled_on)

scenes/menus/options/components/settings_toggle.gd

@@ -1,7 +1,7 @@
 [gd_scene format=3 uid="uid://tahf2q1d3e74"]
 
 [ext_resource type="Theme" uid="uid://cvitou84ni7qe" path="res://scenes/ui_elements/components/theme.tres" id="1_qb52c"]
-[ext_resource type="Script" uid="uid://c63sfg6wgj2uy" path="res://scenes/menus/options/components/fullscreen_toggle.gd" id="2_qb52c"]
+[ext_resource type="Script" uid="uid://c63sfg6wgj2uy" path="res://scenes/menus/options/components/settings_toggle.gd" id="2_qb52c"]
 
 [node name="VideoSettings" type="VBoxContainer" unique_id=1199621136]
 offset_left = 96.0
@@ -21,12 +21,17 @@ text = "Video Settings"
 
 [node name="GridContainer" type="GridContainer" parent="." unique_id=277212195]
 layout_mode = 2
-columns = 2
+theme_override_constants/v_separation = 0
 
-[node name="CheckButton" type="CheckButton" parent="GridContainer" unique_id=409098937]
+[node name="ShowControlsButton" type="CheckButton" parent="GridContainer" unique_id=153771304]
+layout_mode = 2
+text = "Show Controls"
+script = ExtResource("2_qb52c")
+setting = &"show_input_hud"
+
+[node name="FullscreenButton" type="CheckButton" parent="GridContainer" unique_id=409098937]
 layout_mode = 2
 size_flags_horizontal = 3
 text = "Fullscreen"
 script = ExtResource("2_qb52c")
-
-[connection signal="toggled" from="GridContainer/CheckButton" to="." method="_on_check_button_toggled"]
+setting = &"fullscreen"

…ions/components/fullscreen_toggle.gd.uid …ptions/components/settings_toggle.gd.uidscenes/menus/options/components/fullscreen_toggle.gd.uid renamed to scenes/menus/options/components/settings_toggle.gd.uid scenes/menus/options/components/fullscreen_toggle.gd.uid renamed to scenes/menus/options/components/settings_toggle.gd.uid

@@ -63,7 +63,12 @@ func _on_scene_changed() -> void:
 
 
 func _update_visibility() -> void:
-	visible = not get_tree().paused and not Transitions.is_running() and (player or sokoban_ruleset)
+	visible = (
+		Settings.show_input_hud
+		and not get_tree().paused
+		and not Transitions.is_running()
+		and (player or sokoban_ruleset)
+	)
 
 
 func _notification(what: int) -> void: