build.gradle

apply plugin: 'signing'
apply plugin: 'osgi'
apply plugin: 'maven-publish'

group = "org.hamcrest"
version = "2.3-SNAPSHOT"

subprojects {
    apply plugin: 'checkstyle'
    apply plugin: 'java-library'

    sourceCompatibility = JavaVersion.VERSION_1_7
    targetCompatibility = JavaVersion.VERSION_1_7

    group = rootProject.group
    version = rootProject.version

    repositories {
        mavenCentral()
    }

    checkstyle {

        project.ext.checkstyleVersion = '6.18'
            //works with a JDK 7 version which is supposed to be supported although
            //deprecated, see https://github.com/hamcrest/JavaHamcrest/pull/211 for
            //the discussion about the support

        sourceSets = [ project.sourceSets.main, project.sourceSets.test ]
        ignoreFailures = false
        configFile = file("${project.rootDir}/checkstyle.xml")

        configurations {
            checkstyle
        }

        dependencies{
            assert project.hasProperty("checkstyleVersion")
            checkstyle "com.puppycrawl.tools:checkstyle:${checkstyleVersion}"
        }
    }

    test {
        testLogging {
            exceptionFormat = 'full'
        }
    }

    task sourcesJar(type: Jar) {
        classifier = 'sources'
        from sourceSets.main.allSource
    }

    task javadocJar(type: Jar) {
        classifier = 'javadoc'
        from javadoc
    }
}

def pomConfigurationFor(String pomName, String pomDescription) {
    return {
        name = pomName
        description = pomDescription
        url = 'http://hamcrest.org/JavaHamcrest/'

        scm {
            connection = 'scm:git:git://github.com:hamcrest/JavaHamcrest.git'
            developerConnection = 'scm:git:ssh://github.com:hamcrest/JavaHamcrest.git'
            url = 'https://github.com/hamcrest/JavaHamcrest'
        }

        licenses {
            license {
                name = 'BSD License 3'
                url = 'http://opensource.org/licenses/BSD-3-Clause'
            }
        }

        developers {
            developer {
                id = 'joewalnes'
                name = 'Joe Walnes'
            }
            developer {
                id = 'npryce'
                name = 'Nat Pryce'
            }
            developer {
                id = 'sf105'
                name = 'Steve Freeman'
            }
        }
    }
}

def publishToOssrh = project.hasProperty('ossrhUsername') && project.hasProperty('ossrhPassword')

publishing {
    publications {
        def hamcrestProject = project(':hamcrest')
        hamcrest(MavenPublication) {
            from hamcrestProject.components.java
            artifactId hamcrestProject.name
            artifact hamcrestProject.sourcesJar
            artifact hamcrestProject.javadocJar
            pom pomConfigurationFor(
                    'Hamcrest',
                    'Core API and libraries of hamcrest matcher framework.')
        }

        def hamcrestCoreProject = project(':hamcrest-core')
        hamcrestCore(MavenPublication) {
            from hamcrestCoreProject.components.java
            artifactId hamcrestCoreProject.name
            artifact hamcrestCoreProject.sourcesJar
            artifact hamcrestCoreProject.javadocJar
            pom pomConfigurationFor(
                    'Hamcrest Core',
                    'Core Hamcrest API - deprecated, please use "hamcrest" instead')
        }

        def hamcrestLibraryProject = project(':hamcrest-library')
        hamcrestLibrary(MavenPublication) {
            from hamcrestLibraryProject.components.java
            artifactId hamcrestLibraryProject.name
            artifact hamcrestLibraryProject.sourcesJar
            artifact hamcrestLibraryProject.javadocJar
            pom pomConfigurationFor(
                    'Hamcrest Library',
                    'A library of Hamcrest matchers - deprecated, please use "hamcrest" instead')
        }

        def hamcrestJUnit5TestsProject = project(':hamcrest-junit5-tests')
        hamcrestJUnit5Tests(MavenPublication) {
            from hamcrestJUnit5TestsProject.components.java
            artifactId hamcrestJUnit5TestsProject.name
            artifact hamcrestJUnit5TestsProject.sourcesJar
            artifact hamcrestJUnit5TestsProject.javadocJar
            pom pomConfigurationFor(
                    'Hamcrest JUnit 5 Tests',
                    'A test suite for Hamcrest assumptions using JUnit 5')
        }

        def hamcrestJUnit4TestsProject = project(':hamcrest-junit4-tests')
        hamcrestJUnit4Tests(MavenPublication) {
            from hamcrestJUnit4TestsProject.components.java
            artifactId hamcrestJUnit4TestsProject.name
            artifact hamcrestJUnit4TestsProject.sourcesJar
            artifact hamcrestJUnit4TestsProject.javadocJar
            pom pomConfigurationFor(
                    'Hamcrest JUnit4 Tests',
                    'A test suite for Hamcrest assumptions using JUnit 4')
        }

        def hamcrestJUnit4JUnit5TestsProject = project(':hamcrest-junit4-junit5-tests')
        hamcrestJUnit4JUnit5Tests(MavenPublication) {
            from hamcrestJUnit4JUnit5TestsProject.components.java
            artifactId hamcrestJUnit4JUnit5TestsProject.name
            artifact hamcrestJUnit4JUnit5TestsProject.sourcesJar
            artifact hamcrestJUnit4JUnit5TestsProject.javadocJar
            pom pomConfigurationFor(
                    'Hamcrest Hybrid JUnit 4/JUnit 5 Tests',
                    'A test suite for Hamcrest assumptions using hybrid JUnit 4/JUnit 5')
        }
    }
    repositories {
        if (publishToOssrh) {
            maven {
                def snapshotRepoUrl = "https://oss.sonatype.org/content/repositories/snapshots/"
                def stagingRepoUrl  = "https://oss.sonatype.org/service/local/staging/deploy/maven2/"
                url = version.contains('SNAPSHOT') ? snapshotRepoUrl : stagingRepoUrl
                credentials {
                    username = ossrhUsername
                    password = ossrhPassword
                }
            }
        }
    }
}

signing {
    required { publishToOssrh }
    sign publishing.publications.hamcrest
    sign publishing.publications.hamcrestCore
    sign publishing.publications.hamcrestLibrary
    sign publishing.publications.hamcrestJUnit5Tests
    sign publishing.publications.hamcrestJUnit4Tests
    sign publishing.publications.hamcrestJUnit4JUnit5Tests
}