puppet-huskycode-vim/manifests/init.pp at 6838d261fbe214bce86268b7725f1abe4578da99 · huskycode/puppet-huskycode-vim · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
class vim($user, $home_dir) {
  include wget

  validate_string($user)
  validate_absolute_path($home_dir)

  case $::osfamily {
    RedHat: { $vim_package = 'vim-enhanced' }
    default: { $vim_package = 'vim' }
  }

  package { 'vim':
    ensure => installed,
    name   => $vim_package,
  }

  file { [
    "${home_dir}/.vim",
    "${home_dir}/.vim/autoload",
    "${home_dir}/.vim/bundle",
    ] :
    ensure => 'directory',
    owner  => $user,
  }

  file { "${home_dir}/.vimrc.local" :
    owner   => $user,
    replace => false,
    content => "\"Add here your custom options for vim, puppet will not override them\n",
  }

  wget::fetch { 'DownloadPathogen':
    source      => 'https://raw.github.com/tpope/vim-pathogen/master/autoload/pathogen.vim',
    destination => "${home_dir}/.vim/autoload/pathogen.vim",
    verbose     => true
  }

  file { "${home_dir}/.vim/autoload/pathogen.vim":
    owner => $user
  }

  concat { 'vimrc':
    path  => "${home_dir}/.vimrc",
    owner => $user,
    group => 'root',
    mode  => '0664',
  }

  Concat::Fragment {
    target  => 'vimrc',
  }

  concat::fragment { 'rc-header':
    target  => 'vimrc',
    content => "\" generated by Puppet module vim\n\n",
    order   => '05',
  }

  vim::rc { 'vimrc-pathogen':
    content => "execute pathogen#infect()\ncall pathogen#helptags()",
    order   => '10',
  }

  vim::rc { 'vimrc-local':
    content => "if filereadable(glob(\"~/.vimrc.local\"))\n\tsource ~/.vimrc.local\nendif",
  }

  vim::rc { 'syntax on': }
  vim::rc { 'filetype plugin indent on': }
  vim::rc { 'highlight comment ctermfg=darkgray': }
  vim::rc { ':set bg=dark': }

  Package['vim']
  -> File[
    "${home_dir}/.vim",
    "${home_dir}/.vim/autoload",
    "${home_dir}/.vim/bundle"
  ]
  -> Wget::Fetch['DownloadPathogen']
  -> File["${home_dir}/.vim/autoload/pathogen.vim"]
  -> Concat['vimrc']

}