AutoMessage/automessage-loader/build.gradle.kts at b930d93e8a0069acaa7ad10d7fc488268581ab9e · imDMK/AutoMessage · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
import com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar

plugins {
    id("net.minecrell.plugin-yml.bukkit") version "0.6.0"
    id("com.gradleup.shadow") version "9.3.1"
}

dependencies {
    implementation(project(":automessage-core"))
}

tasks.build {
    dependsOn(tasks.test)
    dependsOn(tasks.shadowJar)
}

tasks.withType<ShadowJar> {
    archiveFileName.set("AutoMessage v${project.version} (MC 1.21.x).jar")

    mergeServiceFiles()

    exclude(
        "META-INF/*.SF",
        "META-INF/*.DSA",
        "META-INF/*.RSA",
        "module-info.class",
        "org/intellij/lang/annotations/**",
        "org/jetbrains/annotations/**"
    )

    val relocationPrefix = "com.github.imdmk.automessage.lib"
    listOf(
        "com.eternalcode.multification",
        "dev.rollczi.litecommands",
        "eu.okaeri.configs",
        "net.kyori",
        "org.bstats",
        "org.yaml.snakeyaml",
    ).forEach { pkg ->
        relocate(pkg, "$relocationPrefix.$pkg")
    }

    minimize()
}

bukkit {
    name = "AutoMessage"
    version = project.version.toString()
    apiVersion = "1.21"
    main = "com.github.imdmk.automessage.AutoMessagePluginLoader"
    author = "imDMK (dominiks8318@gmail.com)"
    description = "High-performance plugin for fully customizable automatic server-wide broadcasts."
    website = "https://github.com/imDMK/AutoMessage"
}