Add in better NES RNG [work-in-progress]

The vanilla game's RNG, in many cases, outputs poorly randomized values that form too much of a pattern. I've inserted a better NES RNG to see if that makes things more fun.

This can pretty much replace the need for "Reduce Dripper Variance". In theory it should also reduce the need for the 50/50 Alternating Jar, but that feature seems well-liked so probably can't remove that.

This assumes $F9-$FB in zero page memory is unused - which seems to be true so far in my testing.

Things I specifically don't think should be changed to use this as players are used to how they work:
- Overworld enemy random movement
- Bot/Bit/Myu random movement

Other enemies RNG behavior is a maybe for now.

Potential future things to do:
- Rework Standardize Drops to use a separate seed in SRAM (that will start the same for all players) and is used for drops only, removing the predictability of the current Standardize Drops solution.

Author: initsu

RandomizerCore/Asm/MMC5.s

@@ -603,14 +603,32 @@ ClearPartialDevRAM:
 
 
 .org $a69c
-    jsr SetSoftEnableNmiWithSta
+    jmp SetSoftEnableNmiWithSta
+FREE_UNTIL $a6a0
+
+.reloc
+SetSoftEnableNmiWithSta: ; ends with RTI
+    sta PPUCTRL
+    lda #0
+    sta SoftDisableNmi
+    rti
+
 .org $a6d5
-    jsr SetSoftEnableNmiWithSta
+    jmp ResetMemoryEntryPoint
+FREE_UNTIL $a6d9
+
 .reloc
-SetSoftEnableNmiWithSta:
+; extending this as a point where we hook into "on reset memory"
+ResetMemoryEntryPoint: ; ends with RTS
     sta PPUCTRL
     lda #0
     sta SoftDisableNmi
+
+    lda #.lobyte(RngSeed)
+    sta ZpRng
+    lda #.hibyte(RngSeed)
+    sta ZpRng+1
+
     rts
 
 .segment "PRG5","PRG7"

RandomizerCore/Asm/z2r.inc

@@ -104,6 +104,11 @@ ENABLE_SCANLINE_IRQ = $80
 MulLoReg = $5205
 MulHiReg = $5206
 
+; F0-F4, F9-FB seems unused
+ZpTmp    = $F9  ; nice to have a known disposable byte in zero page
+; New RNG zero page seed (2 bytes)
+ZpRng    = $FA  ; and $FB
+
 ;; Common locations used in the code
 PpuCtrlShadow = $ff
 ScrollPosShadow = $fd

RandomizerCore/Hyrule.cs

@@ -3588,6 +3588,7 @@ private void ChangeMapperToMMC5(Assembler asm, bool preventFlash, bool enableZ2F
         a.Assign("PREVENT_HUD_FLASH_ON_LAG", preventFlash ? 1 : 0);
         a.Assign("ENABLE_Z2FT", enableZ2Ft ? 1 : 0);
         AssignRealPalaceLocations(a);
+        a.Set("RngSeed", 18724); // new in-game ASM rng seed (just picked a number for now)
         a.Code(Util.ReadResource("Z2Randomizer.RandomizerCore.Asm.MMC5.s"), "mmc5_conversion.s");
     }
 
@@ -3695,6 +3696,7 @@ private void ApplyAsmPatches(RandomizerProperties props, Assembler engine, Rando
         FixSoftLock(engine);
 
         RandomizeStartingValues(props, engine, r, rom);
+        rom.BetterAsmRng(engine);
         rom.FixStaleSaveSlotData(engine);
         rom.UseExtendedBanksForPalaceRooms(engine);
         rom.ExtendMapSize(engine);

RandomizerCore/ROM.cs

@@ -838,6 +838,117 @@ public void DisableMusic()
         Put(0x1a975, 0);
     }
 
+    public void BetterAsmRng(Assembler asm)
+    {
+        var a = asm.Module();
+        a.Code("""
+.include "z2r.inc"
+
+.segment "PRG7"
+.reloc
+; From https://github.com/bbbradsmith/prng_6502
+; Returns a random 8-bit number in A (0-255), clobbers Y
+GetBetterRngByteDiscardY:
+	lda ZpRng+1
+	tay ; store copy of high byte
+	; compute ZpRng+1 ($39>>1 = %11100)
+	lsr ; shift to consume zeroes on left...
+	lsr
+	lsr
+	sta ZpRng+1 ; now recreate the remaining bits in reverse order... %111
+	lsr
+	eor ZpRng+1
+	lsr
+	eor ZpRng+1
+	eor ZpRng+0 ; recombine with original low byte
+	sta ZpRng+1
+	; compute ZpRng+0 ($39 = %111001)
+	tya ; original high byte
+	sta ZpRng+0
+	asl
+	eor ZpRng+0
+	asl
+	eor ZpRng+0
+	asl
+	asl
+	asl
+	eor ZpRng+0
+	sta ZpRng+0
+	rts
+
+.reloc
+; Returns a random 8-bit number in A (0-255)
+GetBetterRngByte:
+    sty ZpTmp
+    jsr GetBetterRngByteDiscardY
+    ldy ZpTmp
+    rts
+
+.segment "PRG1"
+; Megmat
+.org $989E
+    jsr GetBetterRngByteDiscardY
+
+; Goriya
+.org $99AB
+    jsr GetBetterRngByte ; (X would be discardable here, but not Y)
+
+; Daira
+.org $9A76
+    jsr GetBetterRngByte
+.org $9A92
+    jsr GetBetterRngByte
+
+; Moby and Moblin generator (which direction to spawn from)
+.org $9B58
+    jsr GetBetterRngByteDiscardY
+
+.segment "PRG4"
+; Stalfos
+.org $970E
+    jsr GetBetterRngByteDiscardY
+
+; Iron Knuckle
+.org $9D2E
+    jsr GetBetterRngByteDiscardY
+.org $9D58
+    jsr GetBetterRngByteDiscardY
+    ldy $df
+.org $9DC7
+    jsr GetBetterRngByteDiscardY
+.org $9DD2
+    jsr GetBetterRngByteDiscardY
+    ldy #$01
+
+; Falling Block Generator
+.org $ABB0
+    jsr GetBetterRngByteDiscardY
+
+; Dripping Column
+.org $B9EB
+    jsr GetBetterRngByte
+
+.segment "PRG7"
+; Bot -- Disabled - don't want to change how the Bot (& similar) enemies act
+;.org $DA15
+;    jsr GetBetterRngByteDiscardY
+; Bot, Bit, Myu
+;.org $DAB0
+;    jsr GetBetterRngByte
+
+; Moa
+.org $DB0D
+    jsr GetBetterRngByteDiscardY
+
+; Raising Bubbles
+.org $DC27
+    jsr GetBetterRngByte ; (X would be discardable here, but not Y)
+    adc $072c    ; add scrolling offset low byte
+    and #$fc     ; allow slightly finer x positioning (snap to every 4th pixel instead of every 16th pixel)
+
+""");
+    }
+
     /// The vanilla game sets up all 3 save slots from PRG in the
     /// title screen.  If there is already valid data in a save slot,
     /// it will keep it.  Note: this includes keeping save slots