mch/build.gradle.kts at main · intsuc/mch · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
import proguard.gradle.ProGuardTask
import java.security.DigestInputStream
import java.security.MessageDigest

plugins {
  java
  id("com.github.johnrengelman.shadow") version "8.1.1"
}

group = "dev.mcenv"
version = "0.16.0"
val brigadierVersion = "1.1.8"

repositories {
  mavenCentral()
  maven("https://libraries.minecraft.net")
  maven {
    url = uri("https://maven.pkg.github.com/mcenv/spy")
    credentials {
      username = project.findProperty("gpr.user") as String? ?: System.getenv("GITHUB_ACTOR")
      password = project.findProperty("gpr.key") as String? ?: System.getenv("GITHUB_TOKEN")
    }
  }
}

dependencies {
  implementation("com.google.code.gson:gson:2.10.1")
  implementation("dev.mcenv:spy:0.5.0")
  implementation("net.sf.jopt-simple:jopt-simple:5.0.4")
  implementation("org.ow2.asm:asm:9.6")
  implementation("org.apache.commons:commons-math3:3.6.1")
  implementation("org.commonmark:commonmark:0.21.0")
  implementation("org.commonmark:commonmark-ext-gfm-tables:0.21.0")
}

tasks.withType(JavaCompile::class) {
  options.encoding = "UTF-8"
  options.release.set(17)
}

tasks.jar {
  manifest {
    attributes(
      "Premain-Class" to "dev.mcenv.spy.Agent",
      "Main-Class" to "dev.mcenv.mch.Main",
    )
  }
}

tasks.shadowJar {
  archiveClassifier.set("shadow")
  archiveVersion.set("")
}

tasks.test {
  useJUnitPlatform()
}

tasks.register<Zip>("zipDatapack") {
  from(layout.projectDirectory.dir("mch"))
  archiveFileName.set("mch.zip")
  isPreserveFileTimestamps = false
  isReproducibleFileOrder = true
}

tasks.register("computeHash") {
  dependsOn(tasks.getByName("zipDatapack"))
  doLast {
    val digest = MessageDigest.getInstance("SHA-256")
    DigestInputStream(layout.buildDirectory.file("distributions/mch.zip").get().asFile.inputStream().buffered(), digest).use { input ->
      input.readBytes()
    }
    layout.buildDirectory.file("distributions/hash").get().asFile.outputStream().buffered().use { output ->
      output.write(digest.digest())
    }
  }
}

tasks.withType<ProcessResources> {
  dependsOn(tasks.getByName("computeHash"))
  from(
    layout.buildDirectory.file("distributions/mch.zip"),
    layout.buildDirectory.file("distributions/hash"),
  )
  filesMatching("version") {
    expand("version" to version)
  }
}

fun ProGuardTask.optimizeJar(optimizationPasses: Int) {
  dependsOn(tasks.getByName("shadowJar"))

  injars(layout.buildDirectory.file("libs/mch-shadow.jar"))
  outjars(layout.buildDirectory.file("libs/mch.jar"))

  System
    .getProperty("java.home")
    .let { javaHome ->
      libraryjars("$javaHome/jmods/java.base.jmod")
      libraryjars("$javaHome/jmods/java.desktop.jmod")
      libraryjars("$javaHome/jmods/java.instrument.jmod")
      libraryjars("$javaHome/jmods/java.sql.jmod")
    }
  libraryjars(configurations.compileClasspath.get().asFileTree.find { it.endsWith("brigadier-$brigadierVersion.jar") })

  keep("@interface dev.mcenv.mch.Keep")
  keep("@dev.mcenv.mch.Keep class *")
  keepclassmembers("class * { @dev.mcenv.mch.Keep *; }")
  keep("class dev.mcenv.spy.Agent { public static void premain(java.lang.String, java.lang.instrument.Instrumentation); }")
  keep("class dev.mcenv.spy.Fork { public static void main(java.lang.String[]); }")

  optimizationpasses(optimizationPasses)
  repackageclasses("mch")
  dontwarn("java.lang.invoke.MethodHandle")
}

tasks.register<ProGuardTask>("optimizeJar") {
  optimizeJar(20)
}

tasks.register<ProGuardTask>("developmentOptimizeJar") {
  optimizeJar(0)
}