ftpclient/build.gradle at main · javaquery/ftpclient · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
plugins {
    id 'java'
    id 'maven-publish'
    id 'signing'
}

sourceCompatibility = 1.8
targetCompatibility = 1.8
group 'com.javaquery'
version '1.0.0'

repositories {
    mavenCentral()
}

dependencies {
    // annotation bases libraries
    compileOnly "org.projectlombok:lombok:${lombokVersion}"
    annotationProcessor "org.projectlombok:lombok:${lombokVersion}"

    implementation 'org.slf4j:slf4j-api:2.0.16'
    implementation 'com.javaquery:util:1.2.7'

    // FTP client libraries
    implementation 'commons-net:commons-net:3.12.0'
    implementation 'com.github.mwiede:jsch:2.27.5'

    implementation 'net.logstash.logback:logstash-logback-encoder:8.0'

    testImplementation 'ch.qos.logback:logback-classic:1.5.16'
    testImplementation 'org.junit.jupiter:junit-jupiter:5.8.1'
    testImplementation 'org.mockftpserver:MockFtpServer:3.2.0'
}

test {
    useJUnitPlatform()
}

java {
    withJavadocJar()
    withSourcesJar()
}

jar {
    manifest {
        attributes(
                'Built-By': "Vicky Thakor"
        )
    }
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            groupId = 'com.javaquery'
            artifactId = 'ftpclient'
            from components.java

            versionMapping {
                usage('java-api') {
                    fromResolutionOf('runtimeClasspath')
                }
                usage('java-runtime') {
                    fromResolutionResult()
                }
            }
            pom {
                name = 'Java FTP Client'
                description = 'Java FTP client to extend interaction of http request'
                url = 'https://github.com/javaquery/ftpclient'
                licenses {
                    license {
                        name = 'MIT'
                        url = 'https://github.com/javaquery/ftpclient/blob/main/LICENSE'
                    }
                }
                developers {
                    developer {
                        id = 'javaquery'
                        name = 'Vicky Thakor'
                        email = 'vicky.thakor@javaquery.com'
                        timezone = '+05:30'
                    }
                }
                scm {
                    connection = 'scm:git:git://github.com/javaquery/ftpclient.git'
                    developerConnection = 'scm:git:ssh://github.com/javaquery/ftpclient.git'
                    url = 'https://github.com/javaquery/ftpclient'
                }
            }
        }
    }
    repositories {
        maven {
            url = layout.buildDirectory.dir('staging-deploy')
        }
    }
}

signing {
    sign publishing.publications.mavenJava
}

javadoc {
    if (JavaVersion.current().isJava9Compatible()) {
        options.addBooleanOption('html5', true)
    }
}