Refactor j target and build tsdll & jconsole

Author: zhihaoy

CMakeLists.txt

@@ -22,10 +22,13 @@ endif()
 
 set(CMAKE_C_STANDARD 11)
 set(CMAKE_C_STANDARD_REQUIRED ON)
+set(CMAKE_C_VISIBILITY_PRESET hidden)
 set(CMAKE_CXX_STANDARD 17)
 set(CMAKE_CXX_STANDARD_REQUIRED ON)
 set(CMAKE_CXX_EXTENSIONS OFF)
+set(CMAKE_CXX_VISIBILITY_PRESET hidden)
 
+find_package(StandardMathLibrary REQUIRED)
 find_package(OpenMP)
 
 set(TARGET_ARCHITECTURE "skylake" CACHE STRING "CPU architecture")
@@ -79,10 +82,10 @@ add_subdirectory(dllsrc)
 add_subdirectory(jsrc/openssl/sha)
 
 if(BUILD_SHARED_LIBS)
-    set_target_properties(j-blis j-openssl-sha j-sleef j-base64 PROPERTIES
+    set_target_properties(j-openssl-sha j-sleef j-base64 PROPERTIES
         POSITION_INDEPENDENT_CODE ON)
 endif()
-target_link_libraries(j PRIVATE j-blis j-openssl-sha j-sleef j-base64)
+target_link_libraries(j PRIVATE j-openssl-sha j-sleef j-base64)
 if(WIN32)
     target_link_libraries(j PRIVATE j-dll)
     target_sources(j PRIVATE dllsrc/jdll.def dllsrc/jdll.rc dllsrc/jdll.tlb)

cmake/FindStandardMathLibrary.cmake

@@ -0,0 +1,68 @@
+# - Try to find how to link to the standard math library, if anything at all is needed to do.
+# On most platforms this is automatic, but for example it's not automatic on QNX.
+#
+# Once done this will define
+#
+#  STANDARD_MATH_LIBRARY_FOUND - we found how to successfully link to the standard math library
+#  STANDARD_MATH_LIBRARY - the name of the standard library that one has to link to.
+#                            -- this will be left empty if it's automatic (most platforms).
+#                            -- this will be set to "m" on platforms where one must explicitly
+#                               pass the "-lm" linker flag.
+#
+# Copyright (c) 2010 Benoit Jacob <jacob.benoit.1@gmail.com>
+#               2020 Susi Lehtola <susi.lehtola@gmail.com>
+# Redistribution and use is allowed according to the terms of the 2-clause BSD license.
+
+
+include(CheckCSourceCompiles)
+
+# a little test program for c math functions.
+
+# We read in the arguments from standard input to avoid the compiler optimizing away the calls
+set(find_standard_math_library_test_program
+"
+#include<fenv.h>
+int main(int argc, char **argv){
+return fetestexcept(argc);
+}")
+
+# first try compiling/linking the test program without any linker flags
+
+set(CMAKE_REQUIRED_FLAGS "")
+set(CMAKE_REQUIRED_LIBRARIES "")
+CHECK_C_SOURCE_COMPILES(
+  "${find_standard_math_library_test_program}"
+  standard_math_library_linked_to_automatically
+)
+
+if(standard_math_library_linked_to_automatically)
+
+  # the test program linked successfully without any linker flag.
+  set(STANDARD_MATH_LIBRARY "")
+  set(STANDARD_MATH_LIBRARY_FOUND TRUE)
+
+else()
+
+  # the test program did not link successfully without any linker flag.
+  # This is a very uncommon case that so far we only saw on QNX. The next try is the
+  # standard name 'm' for the standard math library.
+
+  set(CMAKE_REQUIRED_LIBRARIES "m")
+  CHECK_C_SOURCE_COMPILES(
+    "${find_standard_math_library_test_program}"
+    standard_math_library_linked_to_as_m)
+
+  if(standard_math_library_linked_to_as_m)
+
+    # the test program linked successfully when linking to the 'm' library
+    set(STANDARD_MATH_LIBRARY "m")
+    set(STANDARD_MATH_LIBRARY_FOUND TRUE)
+
+  else()
+
+    # the test program still doesn't link successfully
+    set(STANDARD_MATH_LIBRARY_FOUND FALSE)
+
+  endif()
+
+endif()

dllsrc/CMakeLists.txt

@@ -1,7 +1,6 @@
-add_library(j-dll OBJECT)
+add_library(j-dll OBJECT EXCLUDE_FROM_ALL)
 target_compile_definitions(j-dll PRIVATE $<$<BOOL:BUILD_SHARED_LIBS>:_JDLL>)
 target_compile_definitions(j-dll PRIVATE _CRT_SECURE_NO_WARNINGS)
-set_target_properties(j-dll PROPERTIES EXCLUDE_FROM_ALL YES)
 target_sources(j-dll PRIVATE
     jdll.c
     jdll.h

jsrc/CMakeLists.txt

@@ -1,10 +1,7 @@
-add_compile_definitions(C_NA=0 C_AVX=1 C_AVX2=1 EMU_AVX=1)
-if(WIN32)
-    add_compile_definitions(_CRT_SECURE_NO_WARNINGS)
-endif()
-
 add_library(j)
-set_target_properties(j PROPERTIES CXX_VISIBILITY_PRESET hidden)
+target_compile_definitions(j PRIVATE C_NA=0 C_AVX=1 C_AVX2=1 EMU_AVX=1)
+target_compile_definitions(j PRIVATE $<$<PLATFORM_ID:Windows>:_CRT_SECURE_NO_WARNINGS>)
+target_link_libraries(j PRIVATE ${STANDARD_MATH_LIBRARY})
 set_source_files_properties(aes-ni.c PROPERTIES COMPILE_FLAGS -maes)
 target_sources(j PRIVATE
     a.h
@@ -16,7 +13,6 @@ target_sources(j PRIVATE
     avxintrin-neon.h
     cip_t.h
     cipfloatmm_t.h
-    com_jsoftware_j_JInterface.h
     cpuinfo.h
     cr_t.h
     crc32c.h
@@ -34,9 +30,7 @@ target_sources(j PRIVATE
     js.h
     jt.h
     jtype.h
-    jversion-x.h
     jversion.h
-    jx_utils_jnative.h
     linenoise.h
     m.h
     p.h
@@ -195,8 +189,9 @@ target_sources(j PRIVATE
     crc32c.c
 )
 
-add_library(j-blis OBJECT)
-target_sources(j-blis PRIVATE
+configure_file(jversion-x.h ${CMAKE_CURRENT_SOURCE_DIR}/jversion.h COPYONLY)
+
+target_sources(j PRIVATE
     blis.h
     blis/gemm_c-ref.c
     blis/gemm_int-aarch64.c
@@ -205,3 +200,50 @@ target_sources(j-blis PRIVATE
     blis/gemm_int-sse2.c
     blis/gemm_vec-ref.c
 )
+
+if(NOT BUILD_SHARED_LIBS)
+    return()
+endif()
+
+add_library(tsdll SHARED)
+target_link_libraries(tsdll PRIVATE ${STANDARD_MATH_LIBRARY})
+target_sources(tsdll PRIVATE
+    tsdll.c
+    ../makevs/tsdll/tsdll.def
+)
+
+add_library(linenoise OBJECT EXCLUDE_FROM_ALL)
+target_compile_definitions(linenoise INTERFACE USE_LINENOISE)
+target_compile_definitions(linenoise PUBLIC $<$<PLATFORM_ID:Windows>:_CRT_SECURE_NO_WARNINGS>)
+target_sources(linenoise PRIVATE
+    linenoise.h
+    linenoise.c
+)
+
+add_executable(jconsole)
+target_compile_definitions(jconsole PRIVATE READLINE)
+if(NOT UNIX OR ${CMAKE_SYSTEM_PROCESSOR} MATCHES "^(aarch64|arm)")
+    target_link_libraries(jconsole PRIVATE linenoise)
+endif()
+if("${CMAKE_C_COMPILER_FRONTEND_VARIANT}" STREQUAL "MSVC")
+    target_link_options(jconsole PRIVATE /STACK:0x1000000)
+endif()
+target_link_libraries(jconsole PRIVATE ${CMAKE_DL_LIBS})
+target_sources(jconsole PRIVATE
+    jconsole.c
+    jeload.h
+    jeload.c
+    jlib.h
+    ../makevs/jconsole/jconsole.rc
+    ../makevs/jconsole/resource1.h
+    ../makevs/jconsole/jgray.ico
+)
+
+file(TO_NATIVE_PATH "${PROJECT_SOURCE_DIR}/jlibrary/bin" J_BINPATH)
+file(TO_NATIVE_PATH "/profile.ijs" J_PROFILE_SCRIPT)
+file(GENERATE
+    OUTPUT "$<${is_multi_config}:$<CONFIG>/>profile.ijs"
+    CONTENT "NB. loaded under debug
+BINPATH_z_=: '${J_BINPATH}'
+0!:0<BINPATH,'${J_PROFILE_SCRIPT}'"
+)