nu_scripts/modules/prompt/async_git_prompt/async-git-prompt.nu at 6785ea7ee592a67c2efb8fd422cb89369c5404d8 · kevmoo/nu_scripts · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
# This module exports commands for creating a nushell prompt that computes git status (staged and
# unstaged changes) asynchronously. This can be useful in large git repos when it is slow to obtain
# this information synchronously.

# See README.md for usage.

def unstaged-symbol [] { 'અ' }
def staged-symbol [] { 'જ' }
def in-progress-symbol [] { '…' }
def cached-result-symbol [] { $"·" } #〈
def cache-file [] { '.nu-async-git-prompt-cache'}

def do-async [commands: string] {
    bash -c $"nu -c '($commands)' &"
}

export def async-git-prompt-string [] {
    let cache_path = (cache-path)
    if ($cache_path | is-empty) {
        ""
    } else if ($cache_path | path exists) {
        $"(cached-result-symbol)(open $cache_path | str trim)"
    } else {
        async-git-prompt-compute-sync
    }
}

export def async-git-prompt-compute-sync [] {
    let unstaged = {
        let symbol = if ((git diff --quiet | complete).exit_code == 1) {
            (unstaged-symbol)
        } else {
            ''
        }
        { unstaged: $symbol}
    }
    let staged = {
        let symbol = if ((git diff --cached --quiet | complete).exit_code == 1) {
            (staged-symbol)
        } else {
            ''
        }
        { staged: $symbol}
    }
    # Execute the two slow git commands in parallel and merge the results into a single record
    let symbols = ([ $unstaged $staged ] | par-each { |it| do $it } | reduce {|a b| $a | merge $b})

    $"($symbols | get 'unstaged') ($symbols | get 'staged')" | str trim
}

export def async-git-prompt-refresh-cache [] {
    let cache_path = (cache-path)
    if ($cache_path != null) {
        echo (in-progress-symbol) | save $cache_path
        do-async $"use ($nu.config-path | path expand | path dirname)/async-git-prompt.nu *; async-git-prompt-compute-sync | save ($cache_path)"
    }
}

export def async-git-prompt-delete-cache [] {
    let cache_path = (cache-path)
    if ($cache_path != null) {
        rm -f $cache_path
    }
}

def cache-path [] {
    let dir = if ('.git' | path exists) {
        '.'
    } else {
        do -i { git rev-parse --show-toplevel | str trim -r }
    }
    if ($dir | is-empty) {
        null
    } else {
        $dir | path join (cache-file)
    }
}