build.gradle

import java.time.Duration

def testTaskTimeoutMinutes = providers
  .gradleProperty('testTaskTimeoutMinutes')
  .map { it as int }
  .orElse(5)

subprojects {
  tasks.withType(Test).configureEach {
    failOnNoDiscoveredTests = false
    timeout = Duration.ofMinutes(testTaskTimeoutMinutes.get())
  }

  tasks
    .matching { task -> task.name.toLowerCase().startsWith('test') }
    .configureEach { task ->
      task.timeout = Duration.ofMinutes(testTaskTimeoutMinutes.get())
    }
}

gradle.taskGraph.whenReady { graph ->
  graph.allTasks
    .findAll { task -> task.name.toLowerCase().startsWith('test') && task.hasProperty('timeout') }
    .each { task ->
      task.timeout = Duration.ofMinutes(testTaskTimeoutMinutes.get())
    }
}

tasks.register('sonatypeUpload', Exec) {
    onlyIf {
      if (!System.getenv('SONATYPE_BEARER')) {
        logger.lifecycle('SONATYPE_BEARER is not set. Set SONATYPE_BEARER to activate sonatype upload.')
        return false
      }
      return true
    }
    def uploadScript = './.github/scripts/sonatype-upload.sh'
    if (System.getProperty('os.name').toLowerCase().contains('windows')) {
      commandLine 'bash', uploadScript, 'dist/bundles'
    } else {
      commandLine uploadScript, 'dist/bundles'
    }
    environment 'SONATYPE_BEARER', System.getenv('SONATYPE_BEARER') ?: ''
}

tasks.register('release') {
  dependsOn subprojects.collect { it.tasks.matching { task -> task.name == 'release' } }
  finalizedBy tasks.named('sonatypeUpload')
}