Add a thoroughly revised About Me page

lexi-lambda · lexi-lambda · commit 19881ca3d19d · 2021-07-17T06:57:07.000-05:00
diff --git a/blog/build.rkt b/blog/build.rkt
@@ -93,6 +93,35 @@
   (display "<?xml version=\"1.0\" encoding=\"utf-8\"?>" out)
   (write-xexpr xexpr out))
 
+(define (render-scribble render% main-part out-path
+                         #:dest-dir [dest-dir (path-only out-path)]
+                         #:xref-out [xref-out-path #f])
+  (define main-parts (list main-part))
+  (define out-paths (list out-path))
+  (define renderer (new render% [dest-dir dest-dir]))
+
+  (define traverse-info (send renderer traverse main-parts out-paths))
+  (define collect-info (send renderer collect main-parts out-paths traverse-info))
+  (xref-transfer-info renderer collect-info (load-collections-xref))
+  (define resolve-info (send renderer resolve main-parts out-paths collect-info))
+
+  (match-define (list render-result)
+    (send renderer render main-parts out-paths resolve-info))
+
+  (when xref-out-path
+    (define out-info (send renderer serialize-info resolve-info))
+    (call-with-output-file* #:exists 'truncate/replace
+                            xref-out-path
+                            (λ~>> (write out-info))))
+
+  (define undefined-tags (send renderer get-undefined resolve-info))
+  (unless (empty? undefined-tags)
+    (eprintf "Warning: some cross references may be broken due to undefined tags:\n")
+    (for ([tag (in-list undefined-tags)])
+      (eprintf "  ~s\n" tag)))
+
+  render-result)
+
 (define (build-post-body dep)
   (define src-mod-time (file-or-directory-modify-seconds (post-dep-src-path dep) #f (λ () #f)))
   (define info-mod-time (file-or-directory-modify-seconds (post-dep-info-path dep) #f (λ () #f)))
@@ -101,30 +130,10 @@
      (deserialize (call-with-input-file* (post-dep-info-path dep) read))]
     [else
      (eprintf "~a running <posts>/~a\n" (timestamp-string) (find-relative-path posts-dir (post-dep-src-path dep)))
-     (define renderer (new blog-post-render% [dest-dir build-dir]))
-     (define main-parts (list (post-dep-main-part dep)))
-     (define out-paths (list (post-dep-info-path dep)))
-
-     (define traverse-info (send renderer traverse main-parts out-paths))
-     (define collect-info (send renderer collect main-parts out-paths traverse-info))
-     (xref-transfer-info renderer collect-info (load-collections-xref))
-     (define resolve-info (send renderer resolve main-parts out-paths collect-info))
-
-     (match-define (list (? rendered-post? post-info))
-       (send renderer render main-parts out-paths resolve-info))
-
-     (define out-info (send renderer serialize-info resolve-info))
-     (call-with-output-file* #:exists 'truncate/replace
-                             (post-dep-xref-path dep)
-                             (λ~>> (write out-info)))
-
-     (define undefined-tags (send renderer get-undefined resolve-info))
-     (unless (empty? undefined-tags)
-       (eprintf "Warning: some cross references may be broken due to undefined tags:\n")
-       (for ([tag (in-list undefined-tags)])
-         (eprintf "  ~s\n" tag)))
-
-     post-info]))
+     (render-scribble blog-post-render%
+                      (post-dep-main-part dep)
+                      (post-dep-info-path dep)
+                      #:xref-out (post-dep-xref-path dep))]))
 
 (define (build-post-page dep info)
   (define site-path (rendered-post-path info #:file? #t))
@@ -157,13 +166,22 @@
                           out-path
                           (λ~>> (write-xml (feed type posts #:tag tag)))))
 
+(define (build-about-me)
+  (define site-path "/about.html")
+  (eprintf "~a rendering <output>~a\n" (timestamp-string) site-path)
+  (local-require (only-in "posts/about-me.scrbl" [doc main-part]))
+  (render-scribble (blog-standalone-page-render% standalone-page)
+                   main-part
+                   (reroot-path site-path output-dir)))
+
 (define (build-sitemap posts)
   (define site-path "/sitemap.txt")
   (eprintf "~a rendering <output>~a\n" (timestamp-string) site-path)
   (call-with-output-file*
    #:exists 'truncate/replace
    (reroot-path site-path output-dir)
    (λ (out)
+     (displayln (full-url "/about.html") out)
      (for ([post (in-list posts)])
        (displayln (full-url (rendered-post-path post)) out)))))
 
@@ -195,6 +213,7 @@
       (build-index-page total-pages page-number posts #:tag tag))
     (build-feeds posts #:tag tag))
 
+  (build-about-me)
   (build-sitemap all-posts))
 
 (module+ main
diff --git a/blog/build/render/page.rkt b/blog/build/render/page.rkt
@@ -15,6 +15,7 @@
 
 (provide (contract-out
           [page (->* [#:title string? #:body xexpr/c] [#:tag (or/c string? #f)] xexpr/c)]
+          [standalone-page (-> #:title string? #:body (listof xexpr/c) xexpr/c)]
           [post-page (-> rendered-post? xexpr/c)]
           [index-page-title (->* [] [#:tag (or/c string? #f)] string?)]
           [index-page (->i ([total-pages exact-positive-integer?]
@@ -46,7 +47,7 @@
              (ul ([class "navigation-items center"]))
              (ul ([class "navigation-items right"])
                (li (a ([href "/"]) "Home"))
-               (li (a ([href "/resume.html"]) "About Me")))))
+               (li (a ([href "/about.html"]) "About Me")))))
          (section ([role "main"]) ,body)
          (footer
            (div ([class "copyright-notice"]) "© " ,(~a (date-year (current-date))) ", Alexis King")
@@ -56,6 +57,11 @@
            (div "Feeds are available via " (a ([href ,(feed-path 'atom)]) "Atom")
                 " or " (a ([href ,(feed-path 'rss)]) "RSS") "."))))))
 
+(define (standalone-page #:title title #:body body)
+  (page #:title title
+        #:body `(div ([class "content"])
+                  (article ([class "main"]) ,@body))))
+
 (define (post-page info)
   (match-define (rendered-post title-str title date tags body) info)
   (page #:title title-str
diff --git a/blog/build/render/scribble.rkt b/blog/build/render/scribble.rkt
@@ -21,7 +21,7 @@
          setup/dirs
          syntax/parse/define
          threading
-         (only-in xml write-xexpr)
+         (only-in xml write-xexpr xexpr/c)
 
          "../../lang/post-language.rkt"
          "../metadata.rkt"
@@ -30,6 +30,10 @@
 
 (provide base-render%
          blog-post-render%
+         (contract-out
+          [blog-standalone-page-render%
+           (-> (-> #:title string? #:body (listof xexpr/c) xexpr/c)
+               (implementation?/c render<%>))])
 
          blog-render-mixin
          footnotes-render-mixin
@@ -212,6 +216,18 @@
                                              (current-output-file)
                                              (tag->anchor-name (add-current-tag-prefix key)))))
 
+    (define/override (resolve-content i d ri)
+      (cond
+        [(and external-tag-path
+              (link-element? i)
+              (style? (element-style i))
+              (memq 'indirect-link (style-properties (element-style i))))
+         ; Don’t resolve indirect links, or else we’ll get spurious warnings
+         ; about undefined tags.
+         (resolve-content (element-content i) d ri)]
+        [else
+         (super resolve-content i d ri)]))
+
     ;; -------------------------------------------------------------------------
     ;; render
 
@@ -306,7 +322,7 @@
                ['()
                 (if (hash-empty? attrs)
                     '()
-                    (cons 'span attrs))]
+                    (list (cons 'span attrs)))]
                ; Otherwise, add the attributes to the outermost wrapper.
                [(cons (cons outer-tag outer-attrs) wraps)
                 (cons (cons outer-tag (attributes-union outer-attrs attrs)) wraps)]))
@@ -327,14 +343,15 @@
             (wrap-for-style #:attrs (hasheq) `[(a ,(attributes->list attrs*) ,@rendered)])]
 
            [(link-element _ _ tag)
-            (define dest (resolve-get part ri tag))
-            (unless dest
+            (define indirect? (memq 'indirect-link (style-properties style)))
+            (define dest (and (not indirect?) (resolve-get part ri tag)))
+            (unless (or dest indirect?)
               (error 'render "unknown link destination\n  tag: ~e" tag))
 
             (define href
               (match dest
                 ; racket doc reference
-                [(? vector?)
+                [(or #f (? vector?))
                  (define redirect-query
                    (cons (cons 'tag (tag->local-redirect-query-string tag))
                          (url-query external-tag-path)))
@@ -457,6 +474,20 @@
 
     (super-new)))
 
+(define (blog-standalone-page-render% page-template)
+  (class (pygments-render-mixin (blog-render-mixin base-render%))
+    (inherit render-part)
+
+    (define/override (render-one part ri output-file)
+      (define xexpr
+        (page-template
+         #:title (content->string (strip-aux (part-title-content part)) this part ri)
+         #:body (render-part part ri)))
+      (write-xexpr xexpr)
+      xexpr)
+    
+    (super-new)))
+
 ;; The renderer used for actual blog posts, with all the bells and whistles.
 (define blog-post-render%
   (class (pygments-render-mixin (footnotes-render-mixin (blog-render-mixin base-render%)))
diff --git a/blog/lang/post-language.rkt b/blog/lang/post-language.rkt
@@ -36,6 +36,8 @@
                        [footnote-flow (-> symbol? (listof block?) block?)]
 
                        [wikipedia (-> pre-content? ... element?)]
+                       [github-repo (-> string? element?)]
+                       [github-repo* (-> string? pre-content? ... element?)]
                        [hackage-package (-> string? element?)]
                        [hackage-package* (-> string? pre-content? ... element?)]
                        [hackage-module (-> string? string? element?)]
@@ -108,6 +110,16 @@
       ['() '()]))
   (hyperlink (string-append "https://en.wikipedia.org/wiki/" (string-join words "_")) content))
 
+(define (github-repo user+repo)
+  (match user+repo
+    [(regexp #px"^[^/]+/(.+)$" (list _ repo))
+     (github-repo* user+repo repo)]
+    [repo
+     (github-repo* repo repo)]))
+(define (github-repo* repo . pre-content)
+  (define user+repo (if (string-contains? repo "/") repo (string-append "lexi-lambda/" repo)))
+  (apply hyperlink (string-append "https://github.com/" user+repo) pre-content))
+
 ;; -----------------------------------------------------------------------------
 ;; hackage
 
diff --git a/blog/posts/about-me.scrbl b/blog/posts/about-me.scrbl
@@ -0,0 +1,70 @@
+#lang scribble/base
+@(begin
+   (require racket/list
+            scribble/core
+            scribble/html-properties
+            threading
+            "../lang/post-language.rkt")
+
+   (define Scribble @seclink["top" #:doc '(lib "scribblings/scribble/scribble.scrbl")]{Scribble}))
+
+@title{About me}
+
+My name is Alexis King, and I write @hyperlink["https://github.com/lexi-lambda?tab=repositories"]{a lot of software}. I currently live in Chicago.
+
+I’m interested in functional programming, static types, and programming language research, and I try to spend as much time as I can writing Haskell and Racket. I write about some of the things I do @hyperlink["/"]{on this blog}, and I sometimes tweet about them and other things @hyperlink["https://twitter.com/lexi_lambda"]{on Twitter}. I work on a @emph{lot} of open-source projects @hyperlink["https://github.com/lexi-lambda"]{on GitHub}, and you can email me at @hyperlink["mailto:lexi.lambda@gmail.com" "lexi.lambda@gmail.com"].
+
+@section{Things I’ve worked on}
+
+This list is just a smattering of the cooler things I’ve worked on over the past few years. It is neither exhaustive nor particularly scientific in its curation.
+
+@(define separator @elem[#:style "about-me-year-separator" "⁓"])
+@(define (year-events year . items)
+   @para[#:style "about-me-year-events"]{@elem[#:style "about-me-year-label" year] @separator
+     @(~> (map (λ (item) @elem[#:style "about-me-year-entry" item]) items)
+          (add-between (list " " separator " ") #:splice? #t))})
+
+@year-events["2021"
+  @list{Reimplemented @github-repo*["lexi-lambda.github.io"]{this blog} on top of @Scribble, replacing @github-repo{greghendershott/frog}.}
+  @list{Released @github-repo{megaparsack} v1.5, adding support for user-defined parser state and parser lookahead.}]
+
+@year-events["2020"
+  @list{Published @hyperlink["https://dl.acm.org/doi/abs/10.1145/3428297"]{“Macros for DSLs”} with Michael Ballantyne and Matthias Felleisen at OOPSLA.}
+  @list{Presented @hyperlink["https://www.youtube.com/watch?v=0jI-AlWEwYI"]{“Effects for Less”} at ZuriHac 2020 on the design of @github-repo{hasura/eff} and its accompanying @hyperlink["https://github.com/ghc-proposals/ghc-proposals/pull/313"]{GHC proposal} to add delimited continuations to the RTS.}
+  @list{Led a large-scale refactoring effort to statically rule out several classes of bugs in @github-repo{hasura/graphql-engine}.}
+  @list{Opened @hyperlink["https://github.com/ghc-proposals/ghc-proposals/pull/303"]{a GHC proposal} for improving arrow notation.}
+  @list{Started contributing to GHC, including some @hyperlink["https://gitlab.haskell.org/ghc/ghc/-/merge_requests/3041"]{performance fixes} and @hyperlink["https://gitlab.haskell.org/ghc/ghc/-/merge_requests/3115"]{improvements to arrow notation}.}]
+
+@year-events["2019"
+  @list{Published @hyperlink["https://dl.acm.org/doi/abs/10.1145/3371133"]{“Does blame shifting work?”} with Lukas Lazarek, Samanvitha Sundar, Robby Findler, and Christos Dimoulas at POPL.}
+  @list{Released @hackage-package{monad-validate} based on work done for Hasura.}
+  @list{Started working at @hyperlink["https://hasura.io/"]{Hasura}.}]
+
+@year-events["2018"
+  @list{Presented @hyperlink["https://www.youtube.com/watch?v=g6UCeHiKodo"]{“Hackett: a metaprogrammable Haskell”} at Curry On, and again a few months later @hyperlink["https://www.youtube.com/watch?v=5QQdI3P7MdY"]{at Strange Loop}.}
+  @list{Started working on contract systems with Christos Dimoulas at Northwestern University.}]
+
+@year-events["2017"
+  @list{Released the @hackage-package{freer-simple} package.}
+  @list{Presented @hyperlink["https://www.youtube.com/watch?v=bOUgXd9XlJ4"]{“Hackett, a Haskell for Racketeers”} at RacketCon.}
+  @list{Started working on @github-repo*["hackett"]{Hackett}, a Haskell-like language embedded in Racket.}]
+
+@year-events["2016"
+  @list{Started learning about type systems to explore ideas inspired by @seclink["top" #:doc '(lib "turnstile/scribblings/turnstile.scrbl") #:indirect? #t]{Turnstile}.}
+  @list{Presented @hyperlink["https://www.youtube.com/watch?v=TfehOLha-18"]{“Languages in an Afternoon”} at RacketCon.}
+  @list{Released the @github-repo{megaparsack} and @github-repo{scripty} Racket libraries.}
+  @list{Started writing Haskell professionally for the first time.}]
+
+@section{About this blog}
+
+This blog is powered by @Scribble, an unusually flexible document preparation system written in @hyperlink["https://racket-lang.org/"]{Racket}. Unlike most markup languages, every Scribble document is a @emph{program} that evaluates to a document, which can then be rendered using one of a number of different backends. Scribble provides a TeX-like notation for writing such programs, but unlike TeX—which is essentially an overgrown macro preprocessor—Scribble is a full-fledged functional programming language. In fact, the Scribble syntax is really just an alternate notation for Racket itself, so all the libraries and abstractions available in Racket can be used more or less directly in a Scribble document.
+
+This makes Scribble a remarkably powerful tool for writing prose documents, and indeed, it serves as the foundation for Racket’s @hyperlink["https://docs.racket-lang.org/"]{best-in-class documentation system}, among other things. Using it to power a blog is perhaps a bit overkill, but it gives me the wonderful ability to define whatever abstractions I desire to make blogging as effortless as possible. For example, after finding myself linking to Hackage packages quite frequently, I decided to define a one-line function:
+
+@pygments-block[#:language "racket"]{
+(define (hackage-package package-name)
+  (hyperlink (string-append "https://hackage.haskell.org/package/" package-name) package-name))}
+
+Now all I have to do is write @code["@hackage-package{lens}"] and I get @hackage-package{lens}. Sure, it’s not exactly mind-blowing, but it’s certainly convenient… and of course, the most significant advantages involve abstractions too elaborate to describe here.
+
+This site is, naturally, open source, so if you’d like to see how all the pieces fit together for yourself, feel free to clone @github-repo*["lexi-lambda.github.io"]{the GitHub repository}. And if you’re interested in a simple example of what Scribble looks like to use, you might as well take a peek at @hyperlink["https://github.com/lexi-lambda/lexi-lambda.github.io/blob/source/blog/posts/about-me.scrbl"]{the source code for this page in particular}.
diff --git a/scss/application.scss b/scss/application.scss
@@ -76,6 +76,14 @@ a {
   transition: color 0.15s ease-in-out;
 }
 
+p, article li, blockquote {
+  margin-bottom: 1.2em;
+
+  @media (min-width: 800px) {
+    margin-bottom: 2em;
+  }
+}
+
 body > section[role=main] {
   $content-padding: 30px;
 
@@ -140,22 +148,14 @@ body > section[role=main] {
         width: fit-content;
       }
 
-      // On large screens they can spill into the margins ton, since we really
+      // On large screens they can spill into the margins a ton, since we really
       // don’t want them to have to scroll.
       @media (min-width: $content-width-max + $content-padding * 2) {
         max-width: $content-width-max;
       }
     }
   }
 
-  p, article li, blockquote {
-    margin-bottom: 1.2em;
-
-    @media (min-width: 800px) {
-      margin-bottom: 2em;
-    }
-  }
-
   // Subscripts and superscripts should not disrupt line spacing.
   sup, sub {
     line-height: 0;
@@ -415,3 +415,22 @@ div.figure, article.main > p > a {
 .no-line-wrapping {
   white-space: nowrap;
 }
+
+// -----------------------------------------------------------------------------
+// styles for the About Me page
+
+.about-me-year-events {
+  margin-bottom: 0.35em;
+  margin-top: 0em;
+  padding-left: 1.2em;
+  text-indent: -1.2em;
+}
+
+.about-me-year-label {
+  font-weight: bold;
+  font-size: 1.1em;
+}
+
+.about-me-year-separator {
+  margin: 0.25em;
+}
