uul/uul.asm at master · linuxthor/uul · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
BITS 64
osabi 0x09               ; FreeBSD

global _start
_start:
    mov  rax, 12        ; Haiku create_sem / BSD chdir / Linux brk
    mov  rdi, tmp
    mov  rsi, tmp
    syscall

    cmp  rax, 0xffff
    jl   maybe_haiku

linux:
    mov  rax, 1          ; Linux sys_write
    mov  rdi, 1
    mov  rsi, linz
    mov  rdx, lbyte
    syscall

    mov  rax, 60         ; Linux sys_exit
    mov  rdi, 42
    syscall

maybe_haiku:
    cmp  rax, 1
    jl   bors

haiku:
    ;
    ; Haiku code
    ;
    mov  rax, 144         ; Haiku
    mov  rdi, 1
    mov  rsi, 0
    mov  rdx, hmsg
    mov  r10, hlen
    syscall

    jmp  hexit

bors:
    ;
    ; SunOS code
    ;
    mov rdi, sunz
    mov rax, 12            ; chdir
    syscall

    cmp rax,0
    jne bsd

    mov rdi,1
    mov rsi,suno
    mov rdx,sunob
    mov rax,4
    syscall

    jmp bexit

    ;
    ; BSD code
    ;
bsd:
    mov rdi,1
    mov rsi,obsd
    mov rdx,obyte
    mov rax,4            ; sys_write
    syscall

bexit:
    mov rdi,69
    mov rax,1            ; sys_exit
    syscall

hexit:
    mov rdi, 0
    mov rax, 56
    syscall

section .data
    sunz db '/system',0
    tmp  db '/tmp',0
    suno db 'SunOS',0x0a
    sunob equ $-suno
    obsd db 'BSD',0x0a
    obyte equ $-obsd
    linz db 'Linux',0x0a
    lbyte equ $-linz
    hmsg db 'Haiku',0x0a
    hlen equ $-hmsg

section .note.openbsd.ident
    align   2
    dd      8
    dd      4
    dd      1
    db      'OpenBSD',0
    dd      0
    align   2

section .note.netbsd.ident
    dd      7,4,1
    db      'NetBSD',0
    db      0
    dd      200000000

section .comment
    db      0,"GCC: (GNU) 4.2.0",0          ; Haiku