check-tooling.fish

#!/usr/bin/env fish

set cmds_not_outputting_names fzf pipx rng xsv

function check_and_print_version -a command
    which $command &> /dev/null
    if test $status -eq 0
        # Get version string
        if test $command = "eza"
            set cmd_version ($command --version | awk 'NR==1 {name=$1} NR==2 {version=$1} END {print name, version}')
        else
            set cmd_version ($command --version | head -n 1)

            if contains $command $cmds_not_outputting_names
                set cmd_version "$command $cmd_version"
            end
        end
        set_color --bold green
        echo "[✔] $cmd_version"
    else
        set_color --bold red
        echo "[✗] $command"
    end
    set_color normal
end

set_color --bold yellow
echo "General purpose:"
for command in ack ast-grep bat btm dust eza fd fzf hexyl htop jq mlr ncdu ouch rg rng sad sd sk tldr watchexec xsv yazi yq
    check_and_print_version $command
end
echo

set_color --bold yellow
echo "Development:"
for command in bench black cargo delta difft emacs git grex just pipx python ruff uv
    check_and_print_version $command
end