refactor: Reorganize test configuration and add GTest support

Author: FrozenLemonTee

CMakeLists.txt

@@ -18,13 +18,15 @@ target_sources(mcpplibs-templates
         ${MODULE_SOURCES}
 )
 
-# Test
-add_executable(templates_test tests/main.cpp)
-target_link_libraries(templates_test PRIVATE mcpplibs-templates)
-
-enable_testing()
-add_test(NAME mcpplibs-templates-test COMMAND templates_test)
-
 # Example
 add_executable(basic examples/basic.cpp)
 target_link_libraries(basic PRIVATE mcpplibs-templates)
+
+# Test
+option(BUILD_TESTING "Build the testing directories" ON)
+
+if (BUILD_TESTING)
+    include(CTest)
+    enable_testing()
+    add_subdirectory(tests)
+endif()

tests/CMakeLists.txt

@@ -0,0 +1,47 @@
+enable_testing()
+
+if(NOT TARGET GTest::gtest)
+	include(FetchContent)
+
+	set(GTEST_VERSION_STABLE release-1.12.1 CACHE STRING "Stable GTest version")
+	set(GTEST_VERSION_LATEST v1.16.0 CACHE STRING "Latest GTest version")
+
+	if(NOT DEFINED GTEST_REPO)
+		set(REPO_PRIORITY_LIST
+				"git@github.com:google/googletest.git"
+				"https://github.com/google/googletest.git"
+				"https://gitee.com/mirrors/googletest.git"
+		)
+
+		foreach(repo IN LISTS REPO_PRIORITY_LIST)
+			execute_process(
+					COMMAND git ls-remote ${repo} -q
+					RESULT_VARIABLE result
+					OUTPUT_QUIET
+					ERROR_QUIET
+					TIMEOUT 5
+			)
+			if(result EQUAL 0)
+				set(GTEST_REPO ${repo} CACHE STRING "Selected GTest repository")
+				set(GTEST_VERSION ${GTEST_VERSION_LATEST} CACHE STRING "Selected GTest version")
+				message(STATUS "Selected GTest repository: ${repo}")
+				break()
+			endif()
+		endforeach()
+
+		if(NOT GTEST_REPO)
+			message(FATAL_ERROR "All GTest repositories are unavailable!")
+		endif()
+	endif()
+
+	FetchContent_Declare(
+			GTest
+			GIT_REPOSITORY ${GTEST_REPO}
+			GIT_TAG        ${GTEST_VERSION}
+			GIT_SHALLOW    TRUE
+	)
+
+	FetchContent_MakeAvailable(GTest)
+endif()
+
+add_subdirectory(main)

tests/main/CMakeLists.txt

@@ -0,0 +1,17 @@
+enable_testing()
+
+file(GLOB TESTS_SRC "*.cpp")
+
+set(TEST_EXECUTABLE_NAME main_tests)
+add_executable(${TEST_EXECUTABLE_NAME} ${TESTS_SRC})
+
+target_link_libraries(${TEST_EXECUTABLE_NAME} PRIVATE GTest::gtest GTest::gmock GTest::gmock_main GTest::gtest_main)
+target_compile_features(${TEST_EXECUTABLE_NAME} PRIVATE cxx_std_23)
+
+target_link_libraries(${TEST_EXECUTABLE_NAME} PRIVATE ${PROJECT_NAME})
+
+add_test(
+        NAME ${TEST_EXECUTABLE_NAME}
+        COMMAND $<TARGET_FILE:${TEST_EXECUTABLE_NAME}>
+        WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
+)