python-graph-visualization/justfile at main · neo4j/python-graph-visualization · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
root_dir := justfile_directory()
py_dir := root_dir / 'python-wrapper'

py-sync:
    cd python-wrapper && uv sync --group dev --group docs --group notebook --extra pandas --extra neo4j --extra gds --extra snowflake

# check the release version is unpublished and main's CI is green
# example: just prerelease
prerelease:
    python scripts/release/prerelease.py

# bump the version and reset the changelog after a release (default: minor bump)
# examples:
#   just postrelease          # 1.5.0 -> 1.6.0
#   just postrelease patch    # 1.5.0 -> 1.5.1
#   just postrelease major    # 1.5.0 -> 2.0.0
postrelease part="minor":
    python scripts/release/postrelease.py --part {{part}}

py-style:
    just py-sync
    ./scripts/makestyle.sh && ./scripts/checkstyle.sh

py-test:
    cd python-wrapper && uv sync --all-extras --group dev
    cd python-wrapper && uv run --group dev pytest

py-test-gds:
    #!/usr/bin/env bash
    set -e
    ENV_DIR="test-envs/neo4j-gds"
    trap "cd $ENV_DIR && docker compose down" EXIT
    cd $ENV_DIR && docker compose up -d
    cd -
    cd python-wrapper && \
    NEO4J_URI=bolt://localhost:7687 \
    NEO4J_USERNAME=neo4j \
    NEO4J_PASSWORD=password \
    NEO4J_DB=neo4j \
    uv run --group dev --extra gds pytest tests --include-neo4j-and-gds
    cd ..


# this expects the local compose setup to be running.
py-test-gds-sessions filter="":
    #!/usr/bin/env bash
    cd python-wrapper && \
    GDS_SESSION_URI=bolt://localhost:7688 \
    NEO4J_URI=bolt://localhost:7687 \
    NEO4J_USERNAME=neo4j \
    NEO4J_PASSWORD=password \
    uv run --group dev --extra gds pytest tests --include-neo4j-and-gds {{ if filter != "" { "-k '" + filter + "'" } else { "" } }}

local-neo4j-setup:
    #!/usr/bin/env bash
    set -e
    ENV_DIR="test-envs/neo4j-gds"
    cd $ENV_DIR && docker compose up -d

local-neo4j-teardown:
    #!/usr/bin/env bash
    set -e
    ENV_DIR="test-envs/neo4j-gds"
    cd $ENV_DIR && docker compose down

js-dev:
    cd js-applet && yarn && yarn dev

js-test:
    cd js-applet && yarn && yarn test

js-rebuild:
    ./scripts/clean_js_applet.sh && ./scripts/build_js_applet.sh

js-build:
    ./scripts/build_js_applet.sh

streamlit:
    ./scripts/run_streamlit_example.sh

marimo:
    #!/usr/bin/env bash
    set -e
    cd {{py_dir}} && uv run --group notebook marimo run {{root_dir}}/examples/marimo-example.py

marimo-edit:
    #!/usr/bin/env bash
    set -e
    cd {{py_dir}} && uv run --group notebook marimo edit {{root_dir}}/examples/marimo-example.py

ref-docs:
    ./scripts/render_antora_docs.sh

api-docs:
    ./scripts/render_host_api_docs.sh