feat: introduce language.perl (#278)

Author: WolfangAukang

extra/language/perl.nix

@@ -0,0 +1,44 @@
+{ config, lib, pkgs, ... }:
+
+let
+  cfg = config.language.perl;
+  strOrPackage = import ../../nix/strOrPackage.nix { inherit lib pkgs; };
+
+in
+with lib;
+{
+  options.language.perl = {
+    extraPackages = mkOption {
+      type = types.listOf strOrPackage;
+      default = [];
+      example = literalExpression "[ perl538Packages.FileNext ]";
+      description = "List of extra packages (coming from perl5XXPackages) to add";
+    };
+    libraryPaths = mkOption {
+      type = types.listOf types.str;
+      default = [];
+      example = literalExpression "[ ./lib ]";
+      description = "List of paths to add to PERL5LIB";
+    };
+    package = mkOption {
+      type = strOrPackage;
+      default = pkgs.perl;
+      example = literalExpression "pkgs.perl538";
+      description = "Which Perl package to use";
+    };
+  };
+
+  config = {
+    env = [
+      (mkIf (cfg.extraPackages != []) {
+        name = "PERL5LIB";
+        prefix = pkgs.perlPackages.makePerlPath cfg.extraPackages;
+      })
+      (mkIf (cfg.libraryPaths != []) {
+        name = "PERL5LIB";
+        prefix = concatStringsSep ":" cfg.libraryPaths;
+      })
+    ];
+    devshell.packages = [ cfg.package ] ++ cfg.extraPackages;
+  };
+}

tests/extra/language.perl.nix

@@ -0,0 +1,18 @@
+{ pkgs, devshell, runTest }:
+{
+  # Basic test
+  simple =
+    let
+      shell = devshell.mkShell {
+        imports = [ ../../extra/language/perl.nix ];
+        devshell.name = "language-perl-simple";
+      };
+    in
+    runTest "simple" { } ''
+      # Load the devshell
+      source ${shell}/env.bash
+
+      # Has a Perl interpreter
+      type -p perl
+    '';
+}