devshell cli: add source filter

Author: zimbatm

go/devshell/default.nix

@@ -1,6 +1,16 @@
-{ lib, buildGoModule }:
+{ buildGoModule }:
+let
+  source = import ../../nix/source.nix;
+in
 buildGoModule {
   name = "devshell";
-  src = lib.cleanSource ./.;
-  vendorSha256 = "sha256-CksQhzcKuHWihdJeTazQ5EG8aFkZ5cpss90eRCT+ERc=";
+  src = source.filter {
+    path = ./.;
+    allow = [
+      ./go.mod
+      ./go.sum
+      (source.matchExt "go")
+    ];
+  };
+  vendorSha256 = "sha256-NFsQoPDXEeOmyLR2bCgKuRHw2sjhGQbUmHV8bMJzANw=";
 }

nix/source.nix

@@ -0,0 +1,55 @@
+# A standalone source filtering library
+let
+  inherit (builtins)
+    any
+    isFunction
+    isString
+    isPath
+    map
+    stringLength
+    substring
+    ;
+
+  # Copied from the nixpkgs stdlib
+  hasSuffix =
+    # Suffix to check for
+    suffix:
+    # Input string
+    content:
+    let
+      lenContent = stringLength content;
+      lenSuffix = stringLength suffix;
+    in
+    lenContent >= lenSuffix &&
+    substring (lenContent - lenSuffix) lenContent content == suffix;
+
+  # If an argument to allow or deny is a path, transform it to a matcher.
+  #
+  # This probably needs more work, I don't think that it works on sub-folders.
+  toMatcher = f:
+    let
+      path_ = toString f;
+    in
+    if isFunction f then f
+    else
+      (path: type: path_ == toString path);
+in
+{
+  # Match paths with the given extension
+  matchExt = ext:
+    path: type:
+      (hasSuffix ".${ext}" path);
+
+  # A proper filter
+  filter = { path, name ? "source", allow ? [ ], deny ? [ ] }:
+    let
+      allow_ = builtins.map toMatcher allow;
+      deny_ = builtins.map toMatcher deny;
+    in
+    builtins.path {
+      inherit name path;
+      filter = path: type:
+        (builtins.any (f: f path type) allow_) &&
+        (!builtins.any (f: f path type) deny_);
+    };
+}