need enum identifier names

Author: hauner

src/main/groovy/com/github/hauner/openapi/support/Identifier.groovy

@@ -63,6 +63,48 @@ class Identifier {
         sb.toString ()
     }
 
+    /**
+     * converts a Json string as defined by http://www.json.org/ to a valid (upper case) java
+     * enum identifier. One way, ie it is not reversible.
+     *
+     * conversion rules:
+     * characters that are not valid java identifiers will be removed. The characters " ", "_",
+     * "-" (valid or not) are interpreted as word separators and are replaced by "_" and the words
+     * are converted to upper case.
+     *
+     * @param json a valid json "string"
+     *
+     * @return a valid upper case enum java identifier
+     */
+    static String toEnum (String json) {
+        def sb = new StringBuilder()
+
+        def wordSplit = false
+        json.toCharArray ().eachWithIndex { char c, int idx ->
+
+            def cu = c.toUpperCase ()
+            if (idx == 0) {
+                if (isValidStart (c)) {
+                    sb.append (cu)
+                }
+            } else {
+                if (isValidPart (c)) {
+                    if (wordSplit) {
+                        sb.append ("_")
+                        sb.append (cu)
+                        wordSplit = false
+                    } else {
+                        sb.append (cu)
+                    }
+                } else {
+                    wordSplit = true
+                }
+            }
+        }
+
+        sb.toString ()
+    }
+
     private static boolean isValidStart (char c) {
         Character.isJavaIdentifierStart (c) && !isWordSplitPart (c)
     }

src/test/groovy/com/github/hauner/openapi/support/IdentifierSpec.groovy

@@ -35,4 +35,17 @@ class IdentifierSpec extends Specification {
         "a_b" | "aB"  // underscore is valid but unwanted
     }
 
+    @Unroll
+    void "convert json string '#json' to valid java enum identifier '#identifier'" () {
+        expect:
+        Identifier.toEnum (json) == identifier
+
+        where:
+        json  | identifier
+        "a"   | "A"
+        "a b" | "A_B"  // space is invalid
+        "a-b" | "A_B"  // dash is invalid
+        "_ab" | "AB"   // underscore is valid but unwanted
+        "a_b" | "A_B"  // underscore is valid but unwanted
+    }
 }