DynamicSpigotSetting/build.gradle.kts at main · phateio/DynamicSpigotSetting · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
import net.minecrell.pluginyml.bukkit.BukkitPluginDescription

plugins {
    `java-library`
    alias(libs.plugins.yml.bukkit)
    alias(libs.plugins.paperweight.userdev)
}

val versionPlugin = "1.3"
val versionMinecraft = "1.21.11"

group = "io.github.phateio"
version = "$versionPlugin-mc${versionMinecraft.replace('.', '_')}"


repositories {
    mavenCentral()
}

dependencies {
    paperweight.paperDevBundle("$versionMinecraft-R0.1-SNAPSHOT")
}

paperweight {
    reobfArtifactConfiguration = io.papermc.paperweight.userdev.ReobfArtifactConfiguration.MOJANG_PRODUCTION

    javaLauncher = javaToolchains.launcherFor {
        languageVersion = JavaLanguageVersion.of(21)
    }
}

tasks {
    compileJava {
        options.encoding = Charsets.UTF_8.name()
    }
}

bukkit {
    name = project.name
    version = project.version.toString()
    main = "io.github.phateio.dynamicspigotsetting.MainClass"

    apiVersion = "1.13"

    author = "WhiteCat"

    commands {
        register("DynamicSpigotSetting") {
            description = "main command"
            aliases = listOf("dss")

            usage = """
                /<command> <item|exp|> radius
                /<command> reload
            """.trimIndent()

            permission = "dynamicspigotsetting.manage"
        }
    }

    permissions {
        register("dynamicspigotsetting.manage") {
            default = BukkitPluginDescription.Permission.Default.OP
        }
    }
}