pycon/infrastructure/applications/cluster/iam.tf at 00c5306a1c661cebb6c64fbc2b91f883988c2d2a · pythonitalia/pycon · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
resource "aws_iam_instance_profile" "server" {
  name = "pythonit-${terraform.workspace}-server"
  role = aws_iam_role.server.name
}

resource "aws_iam_role" "server" {
  name = "pythonit-${terraform.workspace}-server-role"
  assume_role_policy = data.aws_iam_policy_document.server_assume_role.json
}

resource "aws_iam_role_policy" "server" {
  name   = "pythonit-${terraform.workspace}-server-policy"
  role   = aws_iam_role.server.id
  policy = data.aws_iam_policy_document.server_role_policy.json
}

data "aws_iam_policy_document" "server_assume_role" {
  # allow ecs
  statement {
    effect = "Allow"

    principals {
      type        = "Service"
      identifiers = ["ec2.amazonaws.com", "ecs-tasks.amazonaws.com", "ecs.amazonaws.com"]
    }

    actions = ["sts:AssumeRole"]
  }

  # allow lambda
  statement {
    effect = "Allow"
    principals {
      type = "Service"
      identifiers = ["lambda.amazonaws.com"]
    }
    actions = ["sts:AssumeRole"]
  }
}

data "aws_iam_policy_document" "server_role_policy" {
  statement {
    effect = "Allow"
    actions = [
      "iam:PassRole",
      "ses:*",
      "ecs:*",
      "ecr:*",
    ]
    resources = [
      "*"
    ]
  }

  statement {
    effect    = "Allow"
    actions   = ["cloudwatch:PutMetricData", "logs:*"]
    resources = ["*"]
  }

  statement {
    effect  = "Allow"
    actions = ["s3:*"]
    resources = [
      "arn:aws:s3:::${terraform.workspace}-pycon-backend-media",
      "arn:aws:s3:::${terraform.workspace}-pycon-backend-media/*",
      "arn:aws:s3:::pythonit-${terraform.workspace}-pretix-media",
      "arn:aws:s3:::pythonit-${terraform.workspace}-pretix-media/*",
    ]
  }

  statement {
    actions = [
      "sns:CreatePlatformEndpoint",
      "sns:Publish"
    ]
    resources = ["*"]
    effect    = "Allow"
  }

  statement {
    actions = [
      "sqs:SendMessage",
      "sqs:DeleteMessage",
      "sqs:GetQueueAttributes",
      "sqs:ReceiveMessage",
    ]
    resources = ["*"]
    effect    = "Allow"
  }

  statement {
    actions = [
      "ec2:DescribeAvailabilityZones",
      "ec2:DescribeInstances",
      "ec2:CreateVolume",
      "ec2:AttachVolume",
      "ec2:DetachVolume",
      "ec2:CreateTags",
      "ec2:DeleteVolume",
      "ec2:DescribeVolumes",
    ]
    resources = ["*"]
    effect    = "Allow"
  }

  statement {
    actions = [
      "ssmmessages:CreateControlChannel",
      "ssmmessages:CreateDataChannel",
      "ssmmessages:OpenControlChannel",
      "ssmmessages:OpenDataChannel"
    ]
    resources = ["*"]
    effect    = "Allow"
  }
}

output "iam_role_arn" {
  value = aws_iam_role.server.arn
}