vst3utils/CMakeLists.txt at main · scheffle/vst3utils · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
cmake_minimum_required(VERSION 3.19.0)

project(vst3utils VERSION 1.2.0)

add_library(vst3utils INTERFACE
	"include/vst3utils/buffer.h"
	"include/vst3utils/byteorder_stream.h"
	"include/vst3utils/enum_array.h"
	"include/vst3utils/event_iterator.h"
	"include/vst3utils/events.h"
	"include/vst3utils/message.h"
	"include/vst3utils/norm_plain_conversion.h"
	"include/vst3utils/observable.h"
	"include/vst3utils/parameter_changes_iterator.h"
	"include/vst3utils/parameter_description.h"
	"include/vst3utils/parameter_updater.h"
	"include/vst3utils/parameter.h"
	"include/vst3utils/smooth_value.h"
	"include/vst3utils/string_conversion.h"
	"include/vst3utils/transport_state_observer.h"
	"ReadMe.md"
)

target_include_directories(vst3utils INTERFACE "include")

target_compile_features(vst3utils
    INTERFACE
        cxx_std_17
)

option(VST3UTILS_TESTS "Enable unit test target" OFF)
set(VST3UTILS_TESTS_SDK_PATH "" CACHE PATH "Path to the VST SDK for unit testing")
if(VST3UTILS_TESTS)

	enable_testing()

	set(BUILD_GMOCK 0)
	set(INSTALL_GTEST 0)
	add_subdirectory(tests/googletest)

	add_executable(vst3utils_test
		"tests/buffer_test.cpp"
		"tests/norm_plain_conversion_test.cpp"
		"tests/observable_test.cpp"
		"tests/string_conversion_test.cpp"
		"tests/transport_state_observer_test.cpp"
	)

	target_link_libraries(vst3utils_test
		PRIVATE
			vst3utils
			gtest_main
	)

	target_compile_features(vst3utils_test
		INTERFACE
			cxx_std_17
	)

	if(CMAKE_XCODE_BUILD_SYSTEM EQUAL 12)
		add_custom_command(
			TARGET vst3utils_test
			POST_BUILD
			COMMAND
				codesign --force -s - $<TARGET_FILE:vst3utils_test>
		)
	endif()

	if(SMTG_WIN)
		target_compile_options(vst3utils_test PRIVATE "/utf-8" "/Zc:__cplusplus")
	endif()

	if(VST3UTILS_TESTS_SDK_PATH)
		set(SMTG_ENABLE_VSTGUI_SUPPORT 0)
		set(SMTG_ENABLE_VST3_HOSTING_EXAMPLES 0)
		set(SMTG_ENABLE_VST3_PLUGIN_EXAMPLES 0)
		set(SMTG_ADD_VST3_UTILITIES 0)
		set(SMTG_RUN_VST_VALIDATOR 0)
		set(SMTG_COREAUDIO_SDK_PATH "")
		add_subdirectory("${VST3UTILS_TESTS_SDK_PATH}" "${PROJECT_BINARY_DIR}/vst3sdk")
		smtg_enable_vst3_sdk()

		target_sources(vst3utils_test PRIVATE
			"tests/attribute_list_test.cpp"
			"tests/events_test.cpp"
			"tests/message_test.cpp"
		)

		target_link_libraries(vst3utils_test
			PRIVATE
				sdk_hosting
		)

		if(SMTG_MAC)
			target_link_libraries(vst3utils_test
				PRIVATE
					"-framework CoreFoundation"
			)
		endif()

	endif()

	include(GoogleTest)
	gtest_discover_tests(vst3utils_test)

endif(VST3UTILS_TESTS)