ExtraPlaceholders/build.gradle at main · sheduxdev/ExtraPlaceholders · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
plugins {
    id "java"
    id "java-library"
    id("com.gradleup.shadow") version "${shadowJarVersion}"
}

group = project.findProperty("group") ?: "network.soylu"
version = project.findProperty("version") ?: "v0.1"
description = project.findProperty("description") ?: "Custom PlaceholderAPI expansion"


dependencies {

    compileOnly "org.spigotmc:spigot-api:${project.findProperty("spigotApiVersion")}"
    compileOnly "me.clip:placeholderapi:${project.findProperty("placeholderApiVersion")}"
    compileOnly "xyz.refinedev.practice:BoltAPI:${project.findProperty("boltApiVersion")}"
    compileOnly "xyz.refinedev.phoenix:pxAPI:${project.findProperty("phoenixApiVersion")}"
    compileOnly "org.projectlombok:lombok:${project.findProperty("lombokVersion")}"
    implementation("net.j4c0b3y.CommandAPI:bukkit:${project.findProperty("commandApiVersion")}")
    implementation("net.j4c0b3y:ConfigAPI-core:${project.findProperty("configApiVersion")}")
    annotationProcessor "org.projectlombok:lombok:${project.findProperty("lombokVersion")}"
}

def targetJavaVersion = project.findProperty("targetJavaVersion")?.toInteger() ?: 17

java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    sourceCompatibility = javaVersion
    targetCompatibility = javaVersion

    if (JavaVersion.current() < javaVersion) {
        toolchain {
            languageVersion = JavaLanguageVersion.of(targetJavaVersion)
        }
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = project.findProperty("sourceEncoding") ?: "UTF-8"
    options.compilerArgs << "-parameters"
    options.fork = true

    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17

    if (JavaVersion.current().isJava10Compatible()) {
        options.release.set(targetJavaVersion)
    }
}

processResources {
    def props = [
            version: version,
            name: project.findProperty("projectName") ?: "ExtraPlaceholders",
            description: description,
            minecraftVersion: project.findProperty("minecraftVersion") ?: "1.8.9",
            apiVersion: project.findProperty("apiVersion") ?: "1.8"
    ]

    inputs.properties(props)
    filteringCharset(project.findProperty("sourceEncoding") ?: "UTF-8")

    filesMatching("plugin.yml") {
        expand(props)
    }
}

shadowJar {
    archiveBaseName.set(project.findProperty("projectName") ?: "ExtraPlaceholders")
    archiveClassifier.set("")
    archiveVersion.set(version.toString())

    manifest {
        attributes(
                "Implementation-Title": project.findProperty("projectName"),
                "Implementation-Version": version,
                "Built-By": System.getProperty("user.name"),
                "Built-JDK": System.getProperty("java.version"),
                "Created-By": "Gradle ${gradle.gradleVersion}"
        )
    }

    minimize()
}

build {
    dependsOn shadowJar
}

clean {
    delete project.findProperty("buildDir") ?: "build"
}