Add Nix flake and corresponding direnv config (#10)

Author: lafrenierejm

.envrc

@@ -0,0 +1,3 @@
+if command -v nix >/dev/null 2>/dev/null; then
+    use flake
+fi

.gitignore

@@ -13,3 +13,6 @@
 
 # Dependency directories (remove the comment below to include it)
 # vendor/
+
+# Nix direnv cache
+/.direnv/

README.md

@@ -24,11 +24,15 @@ Currently we only support choosing a single repository at launch, athough maybe
 
 ## How to Use?
 
-You can run this in three easy ways.
-
-1. Download the release from the Github page, and run it on any linux server.
-2. Use the container `sktan/aws-codeartifact-proxy` and run it on any capable host (AWS ECS, AWS EC2, Linux / Windows VM)
-3. Use the pre-built CDK template found in the `cdk` directory and deploy it to your environment (requires Python)
+There are a variety of options for running `aws-codeartifact-proxy`:
+
+- Download the release from the Github page and run it directly on any Linux server.
+- Run the container `sktan/aws-codeartifact-proxy` on any capable host (AWS ECS, AWS EC2, Linux / Windows VM)
+  - The [`cdk` directory](./cdk) contains a CDK template for deployment to AWS (requires Python)
+- Run as a [Nix flake](https://nixos.wiki/wiki/Flakes):
+  ```shell
+  nix run github:sktan/aws-codeartifact-proxy
+  ```
 
 Configuration is done via Environment Variables:
 

flake.lock

@@ -0,0 +1,64 @@
+{
+  description =
+    "An AWS code artifact proxy to allow unauthenticated read access to your code artifacts";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs";
+    flake-utils.url = "github:numtide/flake-utils";
+  };
+
+  outputs = { self, nixpkgs, flake-utils }:
+    {
+      overlays.default = (final: prev: {
+        inherit (self.packages.${final.system}) aws-codeartifact-proxy;
+      });
+    } // flake-utils.lib.eachDefaultSystem (system:
+      let
+        package-name = "aws-codeartifact-proxy";
+        urn = "github.com/sktan/${package-name}";
+
+        pkgs = import nixpkgs { inherit system; };
+
+        aws-codeartifact-proxy = pkgs.buildGoModule {
+          pname = package-name;
+          name = package-name;
+          src = ./src;
+          vendorSha256 = "3MO+mRCstXw0FfySiyMSs1vaao7kUYIyJB2gAp1IE48=";
+          meta = with pkgs.lib; {
+            description =
+              "An AWS code artifact proxy to allow unauthenticated read access to your code artifacts";
+            homepage = "https://${urn}";
+            license = licenses.mit;
+            maintainers = with maintainers; [ lafrenierejm ];
+          };
+        };
+      in rec {
+        packages = flake-utils.lib.flattenTree {
+          # `nix build .#aws-codeartifact-proxy`
+          inherit aws-codeartifact-proxy;
+          # `nix build`
+          default = aws-codeartifact-proxy;
+          # Build an OCI image.
+          # `nix build .#aws-codeartifact-proxy-oci`
+          aws-codeartifact-proxy-docker = pkgs.dockerTools.buildLayeredImage {
+            name = "aws-codeartifact-proxy";
+            tag = "latest";
+            config = {
+              Entrypoint =
+                [ "${aws-codeartifact-proxy}/bin/aws-codeartifact-proxy" ];
+              WorkingDir = "/data";
+              Volumes = { "/data" = { }; };
+            };
+          };
+        };
+
+        # `nix run`
+        apps.default =
+          flake-utils.lib.mkApp { drv = packages.aws-codeartifact-proxy; };
+
+        # `nix develop`
+        devShells.default = pkgs.mkShell {
+          buildInputs = with pkgs; [ go gopls gotools go-tools nixfmt ];
+        };
+      });
+}