AndroidNetworkTools/app/build.gradle at 1fb03131cbc5aa437aa44ec686850f894ee74c88 · stealthcopter/AndroidNetworkTools · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
buildscript {
  repositories {
    mavenCentral()
  }

  dependencies {
    classpath 'com.stanfy.spoon:spoon-gradle-plugin:1.2.2'

    // This is so we can publish straight to Google Play
    classpath 'com.github.triplet.gradle:play-publisher:1.2.2'
  }
}

apply plugin: 'com.android.application'
apply plugin: 'spoon'
apply plugin: 'com.github.triplet.play'
apply plugin: 'org.jetbrains.kotlin.android'

play {
  track = 'beta'
  if (project.hasProperty("ANDROID_NETWORK_TOOLS_SERVICE_ACCOUNT")) {
    serviceAccountEmail ANDROID_NETWORK_TOOLS_SERVICE_ACCOUNT
  }
  pk12File = file('../key.p12')
}

android {
  compileSdkVersion compileSdkVer
  buildToolsVersion buildToolsVer

  defaultConfig {
    applicationId "com.stealthcotper.networktools"
    minSdkVersion minSdkVer
    targetSdkVersion targetSdkVer

    // When updating these, remember to update the vars in the root build.gradle
    versionName "0.4.6"
    versionCode 23

    archivesBaseName = "AndroidNetworkTools"
    testInstrumentationRunner 'androidx.test.runner.AndroidJUnitRunner'
  }

  //check if the keystore details are defined in gradle.properties (this is so the key is not in github)
  if (project.hasProperty("ANDROID_NETWORK_TOOLS_STORE")) {
    signingConfigs {
      //from ~/.gradle/gradle.properties
      release {
        storeFile file(ANDROID_NETWORK_TOOLS_STORE)
        keyAlias ANDROID_NETWORK_TOOLS_ALIAS
        storePassword ANDROID_NETWORK_TOOLS_PASS
        keyPassword ANDROID_NETWORK_TOOLS_KEY_PASS
      }
    }
  }

  buildTypes {
    release {
      if (project.hasProperty("ANDROID_NETWORK_TOOLS_STORE")) {
        signingConfig signingConfigs.release
      }
      minifyEnabled false
      proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
    }
  }
}

// Spoon used for CI / Testing
spoon {
  debug = true
  // To grant permissions to Android M >= devices */
  grantAllPermissions = true
}

dependencies {
  implementation 'androidx.appcompat:appcompat:1.6.1'
  implementation 'com.google.android.material:material:1.8.0'
  implementation project(':library')

  testImplementation 'junit:junit:4.13.2'

  androidTestImplementation 'com.squareup.spoon:spoon-client:1.6.4'
  androidTestImplementation 'androidx.test.espresso:espresso-core:3.5.1'
  androidTestImplementation('androidx.test.espresso:espresso-intents:3.5.1')
}